Revision as of 16:20, 12 September 2014

INTENT

To illustrate specific techniques for macros specifically designed for the Pathfinder RPG system and to demonstrate their use through examples. As you read through this article you will find certain techniques simplified or unused in order to emphasize the topic method. The examples provided are not necessarily meant to be used as-is(Though everything posted is functional). Rather, they're offered as an example of a particular method to be combined with other techniques for you to craft your own comprehensive macros using all techniques you're comfortable with employing.

TIPS AND TECHNIQUES

Spacing: Spacing inside a roll rarely matters, as it does not generally effect the results of a roll. When making macros, spacing everything far apart will make it easier to see where you might have made an error, and to make it easier to adjust later on as needed.

When figuring out result spacing in the chat window, try to get things to fit on as few lines as possible. It makes for cleaner macros and speeds the game along if you can see and comprehend the results easily.

Group your Macros: To save your own screen space and to avoid having dozens of macros combine similar rolls into one macro: Ex: Conversation skills (bluff,sense motive, diplomacy, etc) can all be rolled at once in a single macro, rather than a macro button for each one.

Boolean Math: Using the Identity property of 1 and the multiplicative property of 0, combined with Queries, you can make ON / OFF type switches in your macros. This is as close as you can get to conditional statements in the Macro system. Real If/Then/Else requires Mentor subscriptions and the API. Note: Pathfinder almost always rounds down, so always use the "Floor" function to force it when finding the 1/2 of something. Example: (Two-Handed Weapon Damage)

[[ 1d12 + 5[STR] + ( ?{Two-Handed Weapon?|0}[TwoHanded?] * floor( 5[STR] * .5) ) ]]

Reason: Since regular weapon damage adds 1x your strength, and a Two-handed Weapon adds 1.5x your Strength you can add Query * HalfYourStrength. By using a 1 in your query result, you add the extra 1/2 str. If you reply 0, the added result is zero so effectively just your regular strength.

Calculated Dice Roll: Mostly for Casters where damage of spells is often dependent on your level, you can use math and attributes to determine how many dice to roll. This is also an example of grouping rolls with { } and comparing them with KL1 (keep Lowest One) Example: CureLightWounds does 1d8 + CasterLevel, but only up to level 5 at max, giving us [[ 1d8 + ( { 5 , @{Level} }kl1) ]] This takes the number 5, compares it to your @{Level} attribute, and keeps the lower of the two. If you're level 2, you'll end up rolling 1d8+2. if you're level 12, you'll roll 1d8+5 Note: Grouped rolls like KL1 and Calculated Dice Roll's currently don't play nice with each other. The only way to combine them is to do a plain regular /roll and inside THAT, do your comparisons. For example, Fireball (CasterLevel of d6' up to 10d6) would come out as /r [[ {10, @{CasterLevel} }kl1 ]]d6 Unfortunately that leaves us with the messy graphical dice. It does calculate correctly, though. In these cases, It's common to forgo the level comparison and just put in your level attribute and replace it with the max number when you hit that level (ie: (@level)d6 until you hit level 10 and just make it 10d6

Passive Rolls for GMs: If you have your players keep Perception, Sense Motive, etc attributes defined in their character journals you can use @{Target|Attribute} or @{Selected|Attribute} to determine if the individual made their check without notifying the player that it happened. This assumes that the Tokens are bound to the Character Journal correctly.

/w GM @{Selected|TokenName} Passive Perception [[ @{Selected|Perception} + 10]]

Since it's the GM whispering to the GM, only they see the roll.

Corollary to Passive GM Roll: If your player-base is consistent you can test all their passive checks at the same time and use it as a general macro for anything that might try to stealth, bluff, traps, etc. NOTE: Spacing gets a bit messy after 4 players without reworking it as the Roll20 chat window only gives you 5 lines of text before posting your character name again. Example: (Secretly rolling generic monster's stealth check and comparing it to player's rolled perceptions)

/w GM NPC Stealth[[ (1d20 + ?{Stealth bonus?|0} ) ]]
/w GM Player's Name:[[ 1d20 + @{PlayerName1|Perception} ]]
/w GM Player's Name:[[ 1d20 + @{PlayerName2|Perception} ]]
/w GM Player's Name:[[ 1d20 + @{PlayerName3|Perception} ]]
/w GM Player's Name:[[ 1d20 + @{PlayerName4|Perception} ]]

Calculating Crits: Aside from using plain text to describe what constitutes a Crit, you can use inline rolls to tell you the actual final roll value while rolling the Confirm. Ex: Rapiers crit on an 18-20. If I have a +6 attack bonus, that means you would crit on a total roll of 24,25, or 26. (18+6 or higher) You essentially repeat your attack roll portion and replace 1d20 with your lowest crit range (18). Note that when you don't use a roll, you can't use the [ ] descriptions inside an inline roll. Game Note: Pathfinder Crits are your damage and bonus' rolled multiple times, not the result multiplied.

/me stabs with his Keen LongSpear(19-20x3)!
Attack:[[1d20 + 6[AttackBonus] ]] for [[1d6 + 4[STR] ]] Dmg
Crits on [[ 19 + 6 ]] | Confirm:[[1d20 + 6[AttackBonus] ]]
Addt'l Crit Damage:[[ ( 1d6 + 4[STR] ) + ( 1d6 + 4[STR] ) ]]

EXAMPLES

Initiative: (the decimal point = your total init bonus. Used for breaking ties with enemies rolling the same, higher bonus wins). The &{tracker} part automatically adds the roll to the turn order. You *MUST* have your token selected for this macro to work correctly.

/me leaps into action! [[1d20 + 11.11 &{tracker}]]

Initiative (As an ABILITY on your character journal using Attributes instead. This can just be an attribute for the total initiative bonus and not bother with the math, but calculations can be useful) Note: The benefit of using the full calculation (dex + misc. init bonus) instead of just a flat value, is that it will dynamically update as your dex increases through Cat's Grace or other temporary effects. NOTE:: Due to wiki layout spacing, the macro appears on multiple lines. It should be written as a single continuous line of text.

/me leaps into action! [[1d20 + @{DEX}[Dex] + @{InitBonus}[Traits] + ( @{DEX} + @{InitBonus} )*.100 
&{tracker}[TieBreaker] ]]

Defense - It's convenient to show all your defenses and make all my saving throws in one click. Putting plain numbers inside [[ ]] is just for emphasis.

/me defends himself from the assault!
[DEFENSES]
AC:[[18]]|[[18]]Flat|[[13]]Touch
Fort[[1d20 + 3]]|Ref[[1d20+7]]|Will[[1d20+1]]
CMD:[[19]] Concentration:[[1d20 +11]]

Defense More complex using attributes and token bars, assuming HP and AC are tracked on token bars and it's currently selected). I use a token bar to track AC instead of an attribute because AC changes frequently in PF. The FlatFooted or Touch calculation may change with different class/feats/etc

/me defends himself from the assault!
[DEFENSES]
HP:[[ @{Selected|BAR3 ]] / [[ @{Selected|Bar3|MAX} ]]
AC:[[ @{Selected|Bar1} ]]|[[ @{selected|Bar1} ]]Flat|[[10 + @{DEX} ]]Touch
Fort[[1d20 + @{Fort} ]]|Ref[[1d20+@{Ref} ]]|Will[[ 1d20+@{Will} ]]
CMD:[[ 10d1[BASE] + @{BAB}[BAB] + @{STR}[STR] + @{Dex}[DEX] ]] | Evasion 

Generic Roll: A generic dice roll that asks for how many dice, what sided dice, and what modifiers you are adding to the roll. Mind the spacing around the d?, it matters here.

/me ?{Your Character is...?|doing something}
[[ ?{Number of Dice|1}d?{Type of Die|6} + ?{Modifiers|0} ]]

Weapon 1 Mathematically speaking, power-attack should almost ALWAYS be used, so we don't often keep separate macros without it. Check out the section above on Boolean Math if you want to make an on/off flag for it. NOTE: Attack macros are the one place you definitely want to use a roll query for misc bonus'. It changes constantly in PF. NOTE2:: Due to wiki layout spacing, the first Attack and Confirm are on multiple lines. They should be written as a continuous line of text.

/me grips his GreatSword firmly and swings Powerfully!
Attack:[[1d20 + 5[AttackBonus] -1[PowerAttack] + ?{Misc Bonus/Penalty?|0} ]] for [[2d6 + 6[STR*1.5] + 
3[PowerAttack] + ?{Damage Bonus?|0}[Damage Bonus] ]] Dmg
Crit Threat: 19-20/x2
Confirm:[[1d20 + 5[AttackBonus] -1[PowerAttack] + ?{Misc Bonus/Penalty?|0} ]] for addt'l [2d6 + 6[STR*1.5] + 
3[PowerAttack]+ ?{Damage Bonus?|0}[Damage Bonus] ]]

MultiAttack: (Note: As you get high enough to make 3 or more attacks, you would likely rework it to query main or second attacks or re-arrange the fluff text for better spacing)

/me grips his GreatSword firmly and swings powerfully!
Attack1:[[1d20 + 5 -1[PowerAttack]]] for [[2d6 + 6[STR*1.5] + 3[PowerAttack] ]] Dmg
Crit Threat: 19-20/x2
Confirm1:[[1d20 + 5 -1[PowerAttack]]] for addt'l [[2d6 + 6[STR*1.5] + [PowerAttack] ]] Dmg
Attack2:[[1d20 + 5 -1[PowerAttack] -5 ]] for [[2d6 + 6[STR*1.5] + 3[PowerAttack] ]] Dmg
Crit Threat: 19-20/x2
Confirm2:[[1d20 + 5 -1[PowerAttack] -5 ]] for addt'l [[2d6 + 6[STR*1.5] + 3[PowerAttack] ]] Dmg

MultiAttack: (Using attributes and Queries. This should cover each attack and determines what the bonus' and penalties should be ) NOTE: Complex, but this covers weapon enchantments, misc bonus' such as Bless, and the -5/-10 penalties for your multiple attacks at higher levels. NOTE2: Due to wiki layout spacing, this appears on multiple lines. The macro itself would be continuous line.

/me grips his GreatSword firmly and swings powerfully!
[Melee]
Attack:[[1d20 + @{BAB}[BAB] + @{STR}[STR] + @{EnchantmentBonus} -3[PowerAttack] + ?{Misc Attack Bonus|0}[Misc Bonus]
 - ( (?{Main:0, Second:1, or Third:2 attack?|0})*5 )[BAB Penalties] ]] for [[2d6 + (floor(@{STR}*1.5))[1.5 STR] 
+ 9[PowerAttack] + ?{Misc Damage Bonus?|0} ]] Dmg

Rapid + MultiShot: This is a massive time/sanity saver for those who combine multishot and rapidshot. Also Monk Flurries. Note: Due to spacing, this is extremely bare-bones output and should be explained to the GM. It's VERY condensed to accommodate spacing. The HIT portion should be fleshed out to use attributes and better techniques, but would detract from the example here. Sample Output: The !xx! are the crit target and damage rolls.

[Rapid/Multi]
Hit1 12(!23!):10(!15!)Dmg
Hit2 23(!23!):10(!12!)Dmg
Hit3 1(!18!):7(!9!)Dmg

Actual Macro: and yes, it can be difficult to read, but the output is clean! NOTE:: Due to wiki layout spacing, the first Hit1 is on multiple lines. It should be written as a continuous line of text.

/me draws his bow and peppers his enemies with arrows!
[Rapid/Multi]
Hit1 [[1d20 + 5 -2]](![[20 + 5 -2]]!):[[ { 1d8 + 3 , 1d8 + 3 } ]](![[ { 1d8 + 3 , 1d8 + 3 } + { 1d8 + 3 , 1d8 + 3 } ]]!)Dmg
Hit2 [[1d20 + 5 -2]](![[20 + 5 -2]]!):[[ 1d8 + 3 ]](![[ { 1d8 + @{STR} ,1d8 + @{STR} } ]]!)Dmg
Hit3 [[1d20 + 5 -2 -5]](![[20 + 5 -2 -5]]!):[[ 1d8 + 3 ]](![[ { 1d8 + 3 ,1d8 + 3 } ]]!)Dmg
Hit3[[1d20 + 5 -2 -10]](![[20 + 5 -2 -10]]!):[[ 1d8 + 3 ]](![[ { 1d8 + 3 ,1d8 + 3 } ]]!)Dmg

Stabilization Check: In PF, when you reach negative HP you have to roll a DC 10 Con check with penalties for the number of negative HP you have. If your negative HP exceeds your total CON, well... it's time to roll another character. Written as an Ability, assumes HP are tracked in Bar3 on your token, and you have an attribute named CON that has your bonus in the left field and max Con in the right field.

/me tries to convince himself the large hole in his chest is just a flesh wound...
[Stabilize]
DC 10 Con Check:[[ 1d20 + @{Con}[Con Mod] + @{Selected|Bar3}[Neg HP] ]]
On Fail: Take [[1]] Dmg.
If Neg HP([[ @{Selected|Bar3} * -1 ]]) = Con([[@{Selected|Con|Max} ]]) ... !! DEATH !!

Perception Basic macro; Perception is the most used skillcheck in the game

/me look around and listens carefully...
[Perception][[1d20 + 8 + ?{Favored Terrain/Other Bonus?|0} ]]

Knowledges: The extra blank line keeps them lined up nicely, usually not an issue unless you're a knowledge whore like Wizards.

/me considers the topic thoughtfully...

Linguistic[[ 1d20 + 7 ]] | Appraise[[1d20+10]]
Arcana[[ 1d20 + 15 ]] | Nature[[1d20 + 10]]
Planes[[1d20 + 11]] | Religion[[ 1d20 + 11 ]]
Dungeon[[ 1d20 + 9 ]] | Nobility[[1d20 + 7]]
Engineer[[ 1d20 + 7 ]] | History[[1d20 + 7 +2]]

Athletics: Generally any skillcheck representing a movement action

/me rolls his shoulders and prepares for a feat of ATHLETICS!
Acrobatics:[[1d20 + 10]]
Jump:[[1d20+3]] Climb:[[1d20+8]]
Swim:[[1d20+7]] Ride:[[1d20+3]]
Fly: [[1d20 -1]]

Sneaky: Various rogue-type actions

/me indulges in a bit of legerdemain and skulduggery...
[SNEAKY]
Disable Device: [[ 1d20 + 12 ]]
Sleight of Hand:[[ 1d20 + 7]]
Disguise: [[1d20 + 4]]]
Stealth:[[ 1d20 + 12 ]]

Conversation: Basic Conversation skills

/me tries to remember long-lost conversation skills...
Bluff/*Feint*: [[1d20 + 6]]
Diplomacy:[[1d20 -3 ]]
Intimidate:[[1d20 + 4]]
Sense Motive:[[1d20 + 7]]

Color spray: Complicated spells that also include rolls are excellent for a macro. Avoid transcribing entire spell descriptions though.

/me raises his hands and links his thumbs before a cone of scintillating color erupts from his palms!
[Color Spray]
DC[[14]] Will Neg | SR:[[1d20 + 7]]
2 HD: Unconscious, blinded, stunned [[2d4]] rounds then blinded and stunned 
[[1d4]] rounds, then stunned [[1]] round.
3 or 4 HD:Blinded,stunned [[1d4]] rounds, then stunned [[1]] round
5 or more HD: stunned for [[1]] round.

Grease: Simplest form without anything fancy. Most appropriate for one-shots

/me cups his palm as though he were standing on a mound in a field and chants the verbal component "Uncto"!
[Grease]
DC[[14]] Ref Neg | SR:No
[[10]]ft. radius or single object for [[2]] minutes

Flaming Sphere: Example of fleshing out all the rolls so you don't have to touch the macro itself again, just attributes on your sheet) NOTE: Using 1d1+9 as the base DC instead of just plain 10 enables text descriptions within the macro, like [SpellLevel], which only work when there is a dice roll involved.

/me gestures as though he was molding a small sphere in his hands and utters, "Flamma Globus"!
[Flaming Sphere]
DC[[ 1d1+9[Base] + 2[SpellLevel] + @{Int}[INT] ]] Ref Neg | SR:[[ 1d20 + @{Level}[Level] ]]
Dur:[[ @{Level}[Level] ]] Rd. Rng:[[100 + { @{Gol|Level} * 10 } ]]ft.
Burning Sphere uses caster's move to shift 30ft each round, co-occupying a 5-ft. 
area. Any creature in this area suffers [[3d6]] fire damage.

Mad Monkeys: Assuming augmented summoning. Macros are great for summons and repeat effects

/me scratches, hopping on one leg, strangely ape-like phrases escaping his lips as he chants...
[MadMonkeys]
Rng[[40]]ft|Dur[[7]]rd
Spd[[30]]|Climb[[20]]|Area[[10]]ft
HP[[22+8]]|AC[[15]]
Melee[[2d6]] + DC[[16]] Fort: Nauseated and Deafened [[1]]rd.
Free Act:Disarm/Steal[[ 1d20 + 7[Level] + 5[CHR] ]] vs. CMD

Black Tentacles:

/me closes his eyes while chanting, channeling the horror of Japanese school girls throughout the ages..
[BlackTentacles]
Rng[[170]]ft|Dur[[7]]rd(D)
Area[[20]]ft Radius|SR:No
On caster turn or enter area:
Grapple[[1d20+7[Level]+4[STR]+1[Size] ]] & [[1d6+4[STR] ]] dmg/rd
CMD to escape[[1d1+9[BaseCMD]+7[Level]+4[STR]+1[Size] +5[Bonus]]]
Tentacles Cannot be Damaged, only dispelled

GlitterDust:

/me raises his hands and tosses a handful of glittering dust into the air while canting, "Coruscantes Et Cinere"!
[GlitterDust]
DC:[[10 + 2 + @{Gol|GolInt} +1 ]]Will Neg | SR:No
Dur:[[ @{Level} ]] rds | Rng[[100 + (10*@{Level} ) ]]ft
[[10]]ft. radius, targets blinded and invisible creatures revealed, stealth receive -40 penalty.
Blinded creatures may attempt to save at the end of their turns.

Alchemist Bomb: When bombs and splash weapons miss, you roll for where it actually lands.

/me pulls the pin and counts to 5... NO! I mean 3!!
[Flask]
Hit:[[1d20+5]] for [[1d6+3]]dmg.
Adj. take [[1]] dmg
If Miss, it lands at [[1d8]]
[[1]] | [[2]] | [[3]]
[[4]] | X | [[5]]
[[6]] | [[7]] | [[8]]