Character Vault
Any Concept / Any System
Your System Come To Life
Roll20 for Android
Streamlined for your Tablet
Roll20 for iPad
Streamlined for your Tablet

Personal tools

Complete Guide to Macros & Rolls

From Roll20 Wiki

Jump to: navigation, search

This is meant to serve as a comprehensive guide & starting point for figuring out how the q Text Chat, Dice Rolling, Macros and related things work and interact with each-other, to find the documentation for each, and to list everything you can write/make appear in the q Text Chat.

This is both for Players and Gamemasters who are just writing their own custom rolls or macros to be used in their game, as well as those who build Character Sheets and are creating/editing Roll Buttons for their sheets.

Creating Macros in Roll20 (Nick Olivo)


Text Chat


The q Text Chat-page shows the basic commands that can be used in the chat, such as /roll(/r) for making simple rolls, /em for emoting actions, /w for whispering to someone, and /gmroll( /gr) for sending simple rolls to the GM.

You can write in the q Text Chat normal text without using any commands like /r.

See Chat Commands-sections for examples, or the

Normal macros can't edit stats, only read them. To edit stats with a command, you need to use API in some form.


Main Page: Macros/Formatting

You can use common Markdown to format you text, and to even create hyperlinks in text shown in the chat.

If you hyperlink to to a i Compendium page, it will open up inside Roll20 when clicked.


Markdown is available to let you bold, italic, bold-italic, create a hyperlinks, or include even an image in your macros and text as they appear in the q Text Chat. You can use basic Markdown syntax in your text chat messages. We don't support the entire breadth of everything Markdown can do (like headers), but rather just basic formatting. Here's a quick rundown:

Format Syntax
Italicize Text *text to italicize*
Bold Text **text to bold**
Bold & Italicize Text ***text to bold & italicize***
Code ``Code``
Link to URL [Google](, [Dodge](
Image [Roll20 Logo](

Alternative to adding the markdown into the macros, you can sometimes add the markdown to your Character Attributes, so you can have a universal macro, and make individual adjustment to to how you want each output to look like.


/em his **@{bob|height}** tall, and can be described as: @{bob|description}.

Note on Code: The extra backtick at the start of the code snippet is required due to the backtick character also being the character used to escape commands.

Note on Images: Including an image is just putting in a link to an image. If the link ends in .png, .jpg, .jpeg, or .gif, we will automatically insert an image tag in addition to linking to the source image.

You can use the Markdown formatting in general messages, whispers (/w), descriptions (/desc), and emotes (/em). You can also include Markdown formatting in the values you pass to Roll Templates and it should work fine. For example:
 {{attack= [[1d20]] vs **AC**}}

Styling with CSS

You can further style chat output and Chat Menus using CSS, which is a hack discovered by Oosh.

Here is how you can modify a basic chat menu with colors etc. Take [command name](~ability-name) and turn it into: [command name](~ability-name" style="border:none;background-color:transparent;padding:0px;color:#3452eb;font-weight:bold;)

1. border can be used to create a border around your button. If you are turning the button transparent just leave it set to "none" (without quotes). If you do want a border this short explanation may help: CSS border shorthand

2. background-color removes the pink box by turning it transparent. You can also turn the pink box into another color by substituting a color word such as "aqua" (without quotes). You can find color names here:

3. padding controls how big the clickable space is around your button-name. A px of 0 is no extra clickable space. A px of 5 is a lot of extra clickable space. You will want to play with this to get a space around your button-name that looks good.

4. color sets the color of the name using a hex color code (such as #3452eb). Here is a source of hex color codes:

5. font-weight sets how thick the letters look (such as bold). If you want something other than bold you can use a word (such as lighter) or a number (such as 300). Here is a short guide on font weights:

In the end it will look something like this: /w gm &{template:npcaction} &{noerror} {{rname=@{selected|character_name}}} {{name=@{selected|npc_type}}} {{description=[Macro1](~Macro1" style="border:none;background-color:transparent;padding:0px;color:#3452eb;font-weight:bold;) }}

A note regarding Light/Dark mode: the color(s) you set up here will not change depending on mode, so make sure you select colors that will display well in the mode of your choice.

Other advanced

HTML replacement

Main Page: HTML Entities

When creating some complicated macros, usually involving nesting, you will need to use HTML entities in parts of the code to trick the Roll20 system to make it behave like you want, or some advanced tricks won't work.

Here are some HTML Entities/Escape Characters that are commonly useful to escape when creating advanced Roll20 macros. See HTML Entities or special character for more:

Character Replacement
| (pipe) |
, ,
{ {, ({)
} }, (})
& &, (&)
space  , ( )
= =
_ _
( (
) )
[ [, ([)
] ], (])
< &#60;, (&lt;)
> &#62;, (&gt;)
`(backtick, grave accent) &#96;
*(asterisk) &#42;
! &#33;
"(doublequote) &#34;
# &#35;
-(hyphen) &#45;
@ &#64;


Here is a macro that will not work, because the "Choose a Roll"-query thinks it stops at the first } it encounters, which is on the second row:

?{Choose a Roll|
  STR,/roll 1d20 + 3 + (?{Modifier})|
  DEX,/roll 1d20 + 2 + (?{Modifier})|
  CON,/roll 1d20 + 1 + (?{Modifier})}

Fixed version:

By using HTML entities to replace all } inside "Choose a Roll", it will now correctly process where the query ends.

?{Choose a Roll|
  STR,/roll 1d20 + 3 + (?{Modifier&#125;) |
  DEX,/roll 1d20 + 2 + (?{Modifier&#125;) |
  CON,/roll 1d20 + 1 + (?{Modifier&#125;) }

If you want to change the ?{Modifier}-query to have a default value like ?{Modifier|0}, you will need to replace the |, so the query won't mistakenly think it's the closing | for that option.

?{Choose a Roll|
  STR,/roll 1d20 + 3 + (?{Modifier&#124;0&#125;) |
  DEX,/roll 1d20 + 2 + (?{Modifier&#124;0&#125;) |
  CON,/roll 1d20 + 1 + (?{Modifier&#124;0&#125;) }

Advanced Nesting example:

Here you can make choices, where each choice might have suboptions to choose between, which in turn might have their own suboptions.

?{Name of Query|
   Option 1, ?{value1&#124;
      Option 1A&#44; ?{value1A&amp;#124;
         Option 1A1&amp;#44; value1A1 &amp;#124;
         Option 1A2&amp;#44; value1A2
      &amp;#125; &#124;
      Option 1B&#44; ?{value1B&amp;#124;
         Option 1B1&amp;#44; value1B1 &amp;#124;
         Option 1B2&amp;#44; value1B2 &amp;#124;
         Option 1B3&amp;#44; value1B3
   &#125; |
   Option 2, ?{value2&#124;value2&#125; 

The descision tree goes:


See Advanced Usage for Roll Queries for more examples.

Chat Commands

Main Page: q Text Chat

  • /r, /roll - for making simple rolls. Ex. /r 1d20+5
  • /w - for whispering a message to a person so only they see it. Ex. /w Alice Does the goblin know the paladin?, /w "Bob Smith" Where's the money pouch?!
  • /gr, /gmroll - to make rolls only to the GM. Ex. /gr 2d6+3
  • /em to emote as the character selected. Ex. /em takes out one of his throwing daggers and brandishes it threateningly.
  • /ooc - to message something that is Out-of-character Ex. /ooc I could really use another coffee right now.
  • /talktomyself - To turn off your chat display for all others, including the GM and the chat archive recording. Use it again to turn it back on
  • /fx - used for creating visual effects Ex. /fx beam-acid @{target|Caster|token_id} @{target|Foe|token_id}
  • GM-exclusive:
    • /desc to describe the situation Ex. The old house begins to creak and moan...
    • /as to send a regular chat message as any character, but with no avatar Ex. /as "Sir Bearington" I'm going to eat you for breakfast.
    • /emas emote as any character, similar to /em but with no avatar Ex. /emas Sir Bearington decides to have porridge instead.

Beyond using the various Roll Commands shown on the q Text Chat-page, here are some other examples of what you can write in the q Text Chat:

  • Macros - Start with #, and start typing the macro name, and a list of your macros will be displayed.
    • Example: writing #testmacro in the chat will roll the macro with that name
  • Roll Templates - &{template:name-of-roll-template} {{sectionname(optional)=content of roll template}}.
    • The Default Roll Template is available in any games, other templates are tied to specific Character Sheet Templates. (E.g. you can only access the specific &{template:simple} when you have D&D 5E by Roll20-sheet in the game).
    • Example: &{template:default} {{name=Test Attack}} {{attack=[[1d20]]}} {{damage=[[2d6]]}}
    • This will generate a roll template using the default template, displaying "Test Attack" in the purple title, then on a new row the result of 1d20 roll, and on the third row the 2d6 roll
  • Character Abilities/Character Sheet Button - %{character name|ability or roll button name}
    • Example 1; writing %{Sam Bobbins|initiative} in the chat, will work if there exists a Character with that name, who have a Character Ability/Character Sheet Roll Button by that name
    • Example 2: selecting a Token on the map, and then writing %{selected|initiative} in the chat, will work if the token is linked to a character sheet that has an Ability or Roll button with that name.
  • API commands(available in games hosted by a pro user), - Start with ! to call the API command, and then write and parameters it can take
    • Example: writing !setattr in the chat will trigger an API that uses setattrd as a keyword. Often these commands may have additional parameters, e.g. !setattr --name John --hp|15

Dice Syntax

The Dice Reference page shows how the syntax for the Roll20 dice rolling works, and all the advanced alternatives you can use, such as rolling Fate Dice, or counting successes rather than the sum of the rolls. It also details when the green & red "Critical Success/Failure"-highlights are shown.


Inline Rolls

Main Page: Inline Rolls

The output of a default template that shows an inline roll(yellow box)

If you use simple roll commands/macros like /roll 2d10+5, the whole command is a dice roll. But when you use Roll Template, or have embedded dice rolls with other commands like /em, you use inline rolls, where you wrap [[ ]] around the calculation for it to be processed. The result of "Normal" dice rolls is shown as individual dice images displaying the result on each dice separately, along with the total result.

Inline rolls are just like regular rolls, with the following exceptions:

  • You can use them in any chat message, not just a roll. For example, you can do a regular chat message, an emote(/em), or a whisper(/w), with an inline roll included.
  • They are evaluated completely before any (/roll) commands, so you can use them as "random variables" in your rolls.
  • You will only see the result of the total roll, and you can hover over the result to see the individual dice rolls.
  • Highlights
    • If an inline roll contains a critical success, it will be highlighted with a green box.
    • If there's a critical failure, it's highlighted in red.
    • If it has both (because there was more than one roll), it's in blue.

Also when you mouse-over the inline roll to see the details of the roll, it'll show red and green highlights for the rolls themselves for crits/fumbles.

With inline rolls, the numerical end result is shown in a (yellow) box, and if you hover you mouse over the result, you see the full equation of the roll, along with the result of each.


/em swings their sword and does [[2d6+2]] damage.
&{template:default} {{name=Test Attack}} {{attack=[[1d20+5]]}}

Inline Labels

If you want to include additional comments before the end of the roll (we call them "inline labels"), use square brackets. For example, /roll 2d10+5[Fire Damage] + 3d6[Ice Damage]. Inline labels works both with "normal" rolls and inline rolls.

When these comments are applied directly after a die roll they show up as tool-tips on the dice:

/roll 2d10+5[Fire Damage] + 3d6[Ice Damage]

This is especially useful if a roll contains multiple variables and you want to look up what number comes from what attribute.

You can even use sheet attributes in labels. Especially useful if the name of the stat can be customized by the user, so the corresponding label should change to reflect the name.

/r @{selected|customskill1}d6[@{selected|customskill1name}] + @{selected|str}[str]

Order of Operations

While the Roll20 dice engine does support basic math and math functions such as floor() and ceil(), it is first and foremost a dice engine, and so it has its own order of operations. This means that putting parentheses inside of your dice formula will not always affect the outcome of the roll (for example, you can't force a variable to be interpreted before a macro). Here is the Roll20 Order of Operations:

1. Abilities are expanded (meaning the definition of the ability is placed in the formula anywhere that ability appears; e.g. %{character name|ability_name} becomes /r 1d4).
2. Macros are expanded (e.g. #macro-name becomes /r 1d4).
3. Attribute calls are resolved. (e.g. @{attribute_name} becomes 4)
4. Steps 1-3 are repeated up to 99 levels deep, or there are no longer any expansions required.
5. Roll queries are executed up to 99 levels deep (the player making the roll is asked to provide a value for each query, and that value is substituted in where the roll query appears in the formula).
5b. HTML Entities within roll queries are parsed once after each roll query (e.g. &#125; becomes }, but &amp;#125; becomes &#125;)
6. Inline rolls are executed, starting with the most deeply nested inline roll working upward. The overall result of the inline roll is substituted in place where it appeared in the formula.
7. The remaining roll is executed: first, dice are rolled for any dice (e.g. 2d6 is rolled; including any special dice such as dropped or exploding), then the result of that roll is substituted into the formula.
8. Mathematical functions like floor() and ceil() are executed.
9. The entire remaining formula is evaluated, including observing proper Math Order of Operations (parentheses first, then multiplication/division, then addition/subtraction).
10. Custom Roll Parsing happens.
11. HTML Entities are processed once.
12. The message is sent to q Text Chat as well as the API sandbox.

Thanks goes to Scott C. & Lockbox313 for additional testing in this matter!


The Macros page lists all the the other kind of options for modifying rolls that isn't covered by the Dice Reference-page. Also check the Stupid Roll20 Tricks (and some clever ones)-thread for Advanced and clever tricks that might not be linked on this page yet.

Features include:

Roll Queries

Sometimes you may have a roll (or a macro) which you want to change every time it is rolled. For example, you may want to roll a variable number of dice, or add a different modifier onto the roll each time you perform the action.

Roll Queries allow you to prompt whoever is performing the roll to fill in a value when the roll is made. The syntax for a roll query is:

?{Prompt Message}
/roll ?{Number of Dice}d20
//You can also include a default value:
/roll ?{Number of Dice|1}d20
// 1 would be the default
Drop-down Queries

You can specify a list of options which can be presented to the player, rather than only a free-form text field. Be mindful about if/when you add spaces inside a Roll Query, as having/not having them changes how things work. If the content of the dropdown query includes characters like |,{,}, and,, you will likely need to use HTML replacement for them to make it work.


?{Name of Query|Option1|Option2|Option3|Option4|Option5}


/em attempts ?{Difficulty level|an Easy|a Moderate|a Hard} task.

You can also specify a separate label for each option, instead of displaying the Option itself in the dropdown.

?{Name of Query|Label 1,Option1|Label 2,Option2}

This can be useful if the Option itself is long, or if it's better to describe what the options represent, rather than show exactly what they are.


/r d20+?{Stat:|Strength,2|Dexterity,1}

If you place the drop-down query at the start of a macro, make sure there is no space after the ,, as this will break any macro or command inside it.

?{Attack|Just roll,/r d20+5|Description,/em swings the sword with a result of [[d20+5]]}
non-functional version
?{Attack|Just roll, /r d20+5|Description, /em swings the sword with a result of [[d20+5]]}

Repeating the same-named Roll Query within a macro will prompt the player only once, however the result will be evaluated wherever it is included.

&{template:default} {{name=Test Attack}} {{attack=[[1d20]]}} {{damage=[[2d6+?{Extra Damage?|0}]]}} {{Crit damage=[[12+?{Extra Damage?|0}]]}}

You may also split up Roll Queries on multiple rows to make the code more readable. Extra line breaks in code isn't generally a good idea, and could be good to avoid to not create errors.

/roll 1d20 + ?{Choose an Attack|
   Melee,3[STR] |
   Ranged,2[DEX] |
   Magic,1[INT] }

If you're listing macros in your roll query, you must have a space after the macro name, so Roll20 knows the name ends inside the query.In the below example, the three rolls have been saved into macros on the l Collections-tab which then can be referenced in the macro.

?{Choose an Attack|
   Melee,#str |
   Ranged,#dex |
   Magic,#int }


To some degree, you can nest abilities, macros and queries.

If you start nesting queries too much, you need to start using HTML replacement characters to keep the macros working. Once saved, these macros shouldn't be opened(if saved in the l Collections-tab's Macro section, as opening a macro that have HTML replacement will result in those being converted into regular things, breaking your macro.

  • Drop down Nester google sheet that generates the HTML replacement code needed. by Scott C.
  • HTML entities contains a longer list of all the existing HTML replacement code, of which only few are used/needed in Roll20 context.


Main Page: Macros/Initiative

To send a roll result directly to the t Turn Tracker, first, select the Token you wish to roll initiative for, and then make a roll that includes the &{tracker}-flag. You can also increase/decrease initiative by using &{tracker:+}/&{tracker:-}.

  • /roll 1d20 + 5 &{tracker}
  • &{template:default} {{name=Initiative}} {{Roll=[[1d20+4 &{tracker}]]}}
  • /roll 1d4 + 1 &{tracker:+} (increases the initiative by 1d4+1)
  • /roll 2 &{tracker:-} (decreases the initiative by a flat 2)
  • [[5 &{tracker:-}]] (inline roll that decreases the initiative by a flat 2)

See also: Using Cards for Initiative Order

Referencing values on the turn tracker: by calling @{Tracker|character_id} @{Tracker|character_name}, you can check what values are on the turn tracker. ex. Bobs initiative is @{tracker|Bob}.

Tricks using the t Turn Tracker:

Chat Buttons

There are two types of buttons you can create in the Text Chat to be included in a macro/dicerolling result.

Ability Command Buttons

Ability Command Buttons can be used to call Abilities (or sheet button rolls) from a clickable button in the Text Chat. They are very closely related to API Command Buttons.

Their syntax is as follows:

[Label](~<keyword>|<ability name>)
[Dex Check](~Bob|dexterity)
[Dex Check](~selected|dexterity_save)
[Dex Check](~selected|repeating_attack_$0_attack)

As with Attribute and Ability calls, the keyword is your choice of selected, target or a character_name. You can also use a character_id as a keyword.

If you have an Ability Command Button saved somewhere within one of the tabs of the Character Window, you can choose to omit a keyword:

[Label](~<ability name>)
[Dex Check](~dexterity)

API Command buttons

API Command buttons do not actually use the API—anyone can make and use them. The Chat Menus trick by Keith, uses utilizes them to great length.


If there is a mistake in the macro, or an attribute is missing, the roll might not work at all and only send and error message in the chat.

In some cases you can suppress error message and the roll will try to do what it can while removing the error message.

/roll 1d20 + @{selected|nonexistent_attribute} &{noerror}

Roll Table

If you have Roll Tables on your l Collections-tab, they can be used in rolls & macros.


Let's assume there exist a roll table with the name fumble.

You can roll a table directly in the chat input, or in a macro, simply as 1t[fumble].

Example 2: To roll your "crit-failure" table two time, you would enter /roll 2t[crit-failure]. You can change 2 to whatever number you would like. However, this currently does not work with inline rolls.

You can also roll a table inline in chat or a macro by wrapping it in double square brackets like this [[1t[table-name]]]. Currently, any number beyond 1 does not display for the inline roll, the results are show on mouseover though.

Roll Templates

Main Page: Roll Templates

You can access the Default Roll template in any game, to structure your results in the Text Chat. You simply write the template in the chat/macro( and don't use the /roll).

Roll template default example.JPG
&{template:default} {{name=Test Attack}} {{attack=[[1d20]]}} {{damage=[[2d6]]}}

You can use a Roll Template in general messages (without a command like /desc or /emote) and whispers. You can't use roll templates with the /roll command; instead, Roll Templates are meant to be used with inline rolls. As long as they use inline rolls, you can use Roll Templates with macros, Character Abilities, and sheet authors can use them inside of their Roll Buttons on sheets.

Many character sheets have built in Roll Templates that can only be used with those specific character sheets.


  • Use images with Default Roll Template: If you want to dress up your default template, you can stuff an image in the name portion instead of just text
    • Example: &{template:default}{{name=[x](YOUR_IMAGE_URL#.png)}}{{test=foo}}
  • Overwriting Template Fields in Macros - Oosh


Roll20 Tips and Tricks (Innovative Solutions to Common Problems)(Forum) contains a large amount of tricks and examples of clever uses for macros etc. that is a must to check out.

Here under are mentioned a limited number of the list's tricks(more could be listed or copied entirely to the wiki):


Various ways to use or show images in macros or the chat.

Chat Menus

Idea by Keith Curtis

Creating a Chat Menus for your macros is a great shortcut to have access to many buttons by only calling the chat menu macro.


Main Section: Macros#Token

You can target the stats of tokens(and the stats of a linked character sheet) by two methods, using either @{selected}, or @{target}.


List of token-specific stats you can target with the usual @{} commands, that doesn't need to rely on having a character sheet linked to the token:

  • bar1,bar2,bar3 (max values called with @{bar1|max}, @{bar2|max}, @{bar3|max})
  • token_name
  • token_id

If a character sheet is linked, and you have linked a sheet attribute to one of the bars, you can reference that stat either by targeting the token's bar, or the actual name of the attribute on the sheet.


  • Token **"@{selected|token_name}"** has [[@{selected|bar1}]] out of [[@{selected|bar1|max}]] HP left. - displays the token name and the current/max value of bar1
    • token bar max values need to be referenced with @{attrname|max}, using @{attrname_max} doesn't work.
  • &{template:default} {{name=**Character & Token ID**}} {{Character Name=@{selected|character_name} }} {{**Character ID**= @{selected|character_id} }} {{**Token Name**= @{selected|token_name} }} {{**Token ID**= @{selected|token_id} }} {{**Bar 1**= @{selected|bar1} / @{selected|bar1|max} }} {{**Bar 2**= @{selected|bar2} / @{selected|bar2|max} }} {{**Bar 3**= @{selected|bar3} / @{selected|bar3|max} }}
    • a macro that displays the token_id, token_name and token bar values, as well as the character_id & character_name if token is linked to a sheet.


Main page: @{selected}

When using @{selected}, you need to first select the token you want to use, before making the roll, and you can only have one token using this method.

The selected-keyword will allow you to pull information from the element that is currently selected on the screen when the roll/macro is executed. So for example, if you want to pull the value of Bar 1 from the selected Token during a roll, you can do:

/roll 1d20 + @{selected|bar1}

You can use "bar1", "bar2", or "bar3". In addition, you can also pull an attribute from the Character linked to that token, if there is one:

/roll 1d20 + @{selected|Intelligence}

You can pull the Name of the currently selected tokens by using the "token_name" variable.

/em @{selected|token_name} fires his gun!

If the selected token has a character journal linked to it, you can pull the Name from the character journal instead, using the "character_name" variable.

/em @{selected|character_name} blocks with his shield!

You can also trigger abilities from the linked character journal by using the ability name as a variable.


Finally, we've introduced a third argument for variables, allowing you to pull the "max" of a bar or attribute:

/roll 1d20 + @{Guard|Intelligence|max}
/roll 1d20 + @{selected|bar2|max}

On token bars, you must reference max values with the @{selected|bar1|max} syntax, while for character attributes, both @{selected|attrname|max} and @{selected|attrname_max} works.


Main page: @{target},

When using @{target}, you make the roll first, and then get prompted to select the target token(s), before the roll is then executed. You can target several tokens/characters in a single roll.

/roll @{target|bar2}d6
/roll 1d20 - @{target|strength}

This will bring up a prompt screen for the player to select which token target they are rolling against:


The full syntax for the target variable is:


(Note that target_name is optional if you only have one target. Name can be anything you like, and can include spaces.)

So if you want to have multiple targets in your macro you can do:

@{target|Target1|HP} vs @{target|Target2|AC}

And if you want to use the max of an attribute:

@{target|bar1|max}                                - token max values can only be referenced with "|max"
@{target|HP_max}                                  - max value of HP, from the linked character sheet
@{target|Target1|HP|max}                          - alternative method for the above
@{target|target 1|HP_max} @{target|target 2|HP_max} - check max HP of two tokens
@{target|target 1|HP|max} @{target|target 2|HP|max} - alternative method for the above

Note that if you want to use the "max" flag you must specify the name of the target yourself, even if you just put "target1" as above.

Additionally, if you use the same target_name in multiple attribute queries, you will only get prompted for it once and the same token will be used to fulfill all of the attribute queries. This also applies when you have multi-line macros or commands:

/me strikes out at @{target|foe|character_name}!
**To Hit**: [[1d20+3]] vs. @{target|foe|npc_AC} AC

Token Actions

Token Actions are specially-designated macros and character abilities (with tokens representing a character) which appear whenever a token is selected on the screen. They appear in a bar along the top of your screen, and the contents of the bar are context-sensitive. When you select a token, all macro token actions will be shown, as well as ability token actions for the token's linked character (if applicable).


main page: Journal Command Buttons

Character Attributes

How to reference character/Character sheet Attributes: Journal#Attributes

Each character also have a few pseudo-attributes that always exists, even if there is no sheet or Attributes statted for them

From a custom command, anywhere:

/r 1d20+@{Bob|str}

If macro is saved to a character's A&A-tab, to a token linked to a sheet, or is embedded in the character sheet's button (code):

/me makes a Strength roll of [[1d20+@{str}]]

Repeating Section

Referencing Repeating Attributes

Character Abilities/Roll Buttons

Button Most char sheets have roll buttons, which can be called directly with a %-command.

%{Bob|dexterity} // call the dex roll for a character named bob
%{selected|dexterity} // call the dex roll for the character linked to the selected token


If you have saved custom Abilities to a character's Attributes & Abilities-tab, you can call the ability with the same %-syntax as buttons. These are character-specific, so unless other characters have an ability with the same name, it wont work.


When writing an ability macro, you dont have to specify the characters name, and can call attributes directly(/r 1d20+@{dex})


You can add roll buttons with macros to Handouts, with the help of hyperlinks.


API commands(AKA API calls), start with ! and then the name of the API command, and then write any other parameters for the API. Some API macros can be embedded into regular macros, such as ChatSetAttr. To use any API in macros, the specific APIs need to be installed in the game for them to work. Here are some examples of API commands/macros.

Example 1: writing !wd [[4d6+2]] in the chat will trigger the Script:Wild Dice script to make a custom roll output, rolling 3 normal d6 dice, and one Wild Die, presenting it in a table. If the Wild Die comes up as a "1", it, and the value of the highest dice is removed form the roll total. This is not something that can be done with macros alone, which is why this API was created.


Example 2:

writing !group-init in the chat will trigger the GroupInitiative(must be installed) API that uses group-init as a keyword. This particular API command would roll initiative order for all selected tokens, if the API is configured to know what stats to roll.

Example 3:

writing &{template:default} {{name=Cthulhu}} !modattr --silent --charid @{target|character\_id} --sanity|-{{Sanity damage=[[2d10+2]]}} --corruption|{{Corruption=Corruption increases by [[1]]}}!!! {{description=Text}} in the chat, and selecting a Token on the map, will decrease sanity by 2d10+2 and increase corruption by 1 for the character selected.

This is the ChatSetAttr API, which can be used standalone with the !modattr command, but more notably, can be incorporated into regular macros, resulting in you being able to both make rolls and have the result change the stats.

API Command Buttons

Main Page: API:Chat#API_Command_Buttons

They have simple Markdown formatting:

[Attack Roll](!attackroll)

You can also send them into the chat for others to use, but them needs to use HTML Replacement like with Nesting:

[Attack Roll](!attackroll &#64;{target|token_id} &#91;[1d6+&#63;{Bonus|0}]&#93;)

API Command buttons do not actually use the API — anyone can make and use them. The Chat Menus trick by Keith, uses utilizes them to great length.



Various APIs that primarily help you out by creating API commands & options that can be used in the q Text Chat.

  • ChatSetAttr -- Create, modify, and delete character attributes via chat commands or macros.
  • ChatTurnManager -- A script to simplify Turn Order Management, and move it into chat.
  • Check It Out(Forum) -- allows players to examine nearby objects(tokens) and learn more information about them by having a message appear in the chat. Can be set up with system-specific properties, such as automated Investigation skill checks that reveal more information based on the rolled result. Readme
  • Dialog(Forum) -- a script that makes chat a bit more fun and easier to parse, especially for games that don't use voice. It also makes it much easier to get the GM's attention in a busy game.sourcecode, by Keith
  • DiscreteWhisper -- multi-recipient whispers with asides and buttons
  • emas -- Provides player !emas and !as commands.(emote as)
  • ScriptCards -- A scripting language in a Mod Script. Used to produce nicely formatted output cards for attacks, spells, and other abilities. Successor to PowerCards
  • SuperNotes(Forum) Mod to pull descriptions from token/character descriptions, Bio, GM fields & more as an caht message. Later version comes with 10 different chat template options.
  • PowerCards -- Create nicely formatted output cards for attacks, spells, and other abilities.
  • Message of the Day -- Greets players that log in with the contents of a particular note.
  • Rollable Table Macros -- Use macros and chat commands with rollable tables
  • Changes how normal macros and API Script calls are processed:
    • MetaMacros -- Precompiler enabling C-style textual substitution macros in macro definitions.
    • Meta-Toolbox -- collection of meta scripts
      • SelectManager -- a way to preserve the portions of a message that are present in a user-generated message but lost in an api-generated message (the selected tokens, who sent the message, and the playerid).
    • Category:API Meta Scripts

Relevant API

APIs that have lots of commands or have lot to do with dice rolling.

  • ChatSetAttr - can be used inline & mixed in with other macros, and can edit stats, which normal macros can't
  • ScriptCards - API made to display stats in variety of way in the chat, essentially a sophisticated, API-based version of the Default Roll Template with massive amount of features. It can be used to call other API like ChatSetAttr or TokenMod
  • APILogic -- Gives If/ElseIf/Else Processing, Inline Math operations, and Variable Muling to Other Scripts | APILogic(Forum)
  • SelectManager(Forum) - help other API with properly sharing token selection between other APIs. Often API that can call other APIs doesn't share what tokens are currently selected.
  • libInline(Forum) - provides an easy interface for inlinerolls
  • InsertArg & XRay(Forum) script that gives you a way to interact with information in the game and feed it to the chat and/or other scripts, or to build your own output on the fly.
  • TokenMod – API that can edit any info on tokens. If token's are linked to a character, the changes to token bars extends to the character sheet.
  • CombatMaster(Forum) Manages many facets of combat. It allows for API and Macro calls at various timing points (beginning of each round, beginning of each turn, when a condition is assigned, when a condition is removed).
  • Token Action Maker(Forum)
  • Rollable Table Macros -- a simple script that gets an item from a rollable tables and enters its name as a chat message rather than showing it as a rollable table result
  • Script:Star Wars: Fantasy Flight Games - Dice Roller - API for rolling the custom dice system used in the game
  • It's a Trap! Can be used to create a Trap that can automate rolls related to the trap, both for the trap and for the character(such as saves). There exists a generic one, as well as a number of system-specific version designed with popular sheets in mind(D&D5e, Pathfinder 1E)
  • API:Script Index curated list of Roll20 APIs available

Character Sheet Creation

Info and links to things that are only relevant or usable for when you're Building/Editing Character Sheets. Consult the rest of the guide for general details.

Roll Button

The rest of this guide will help in creating more complicated macros, but the main Button#Roll_Button-page have some concrete examples of how macros are implemented in character sheets.


With the info from Macros, fairly complex outputs to the q Text Chat can be made, but to be able to construct complex and dynamic results based on various factors on your character sheet, you will need to use JavaScript to write Sheet Worker Scripts that modify & construct your roll output dynamically.

Roll Template

When you create/edit a character sheet, you can make your own Roll Templates to make your roll output look like you want, and to do some conditional things such as only showing some sections in case of a critical roll in another sections.

See Creating Roll Templates for how to make your own.

Helper Functions describes what functions you can build into your sheets.

External Tools

Related Pages

  • Complete Guide to Macros & Rolls‎
    • q Text Chat - where the roll results appear, & info on the common chat commands
    • Dice Reference - Comprehensive list of how the Roll20 dice-rolling syntax works, and list the features available
    • Macros - How to create macros, and other info on how the Roll20 qText Chat works, like referencing stats on character sheets, roll queries, nesting macros & initiative
    • Roll Templates - a method of formatting roll results in the chat, with some extra functions
    • Tokens
    • API(Pro Only) - API commands can be used in the qText Chat
  • Forum Tricks

Other Guides


  • add image examples of every macros used, input + output
  • at least one example for each mentioned concept
  • Roll Template examples
  • List rest of the examples from "Stupid Tricks" thread
  • new sections
    • Chat Tooltip
    • Stylus, for tricks like the hidden rolls
  • Split page:
    • macro formatting
    • HTML styling
  • copy tips from Macros/Pathfinder Examples

See Also