Author of script:
Game/System specific? Which one:
Does this script require additional mods to function? If yes, please list them here:
Purpose of script:
Description of intended results:
Screenshots:
Caveats/ Notes:
Script code:

 
Enter script code here

Author of script: David M.
Game/System specific? Which one: Alien TTRPG
Does this script require additional mods to function? If yes, please list them here: N/A
Purpose of script: This example appends URLs to a string variable in a loop and displays the results to a single output line.
Description of intended results: This example appends URLs to a string variable in a loop and displays the results to a single output line (have to prepend alignment and img size tags, then build URL strings, then append closing tag). Here's what I came up with for the Alien TTRPG. You roll a number of base dice, and a number of "stress" dice. Both count 6's as a success, while the stress dice can also add a failure for each roll of 1. Add successes & failures to determine overall result of the check. Here's a couple of example checks, using rollable table graphics for the cool Alien dice and string building variables to put the dice on a single line.
Screenshots:
Caveats/ Notes: N/A
Script code:

 
!scriptcard {{
  --#title|AlienTTRPG Rolls
  --#leftsub|Num Dice ?{Num Dice?|1}
  --#rightsub|Num Stress Dice ?{Num Stress Dice?|0}
  
  --:Initialize Roll Vars|
      --=NumDice|?{Num Dice?}
      --=NumStressDice|?{Num Stress Dice?}  
      --=NumSuccess|0
      --=NumFail|0
  --:String Building Vars| Will store table graphics. Pre-pend opening format tag
      --&DieOutput|+[r]
      --&StressOutput|+[r]

  --:Base Dice Block|
      --+[#990000]BASE ROLLS[/#]|
      --=DieCount|0
      --:BaseDiceLoop|
              --=DieCount|[$DieCount] + 1
              -->RollBase|
              --?[$DieCount] -lt [$NumDice]|BaseDiceLoop
  --:Output Main Dice| but first append closing format tag
      --&DieOutput|+[/r]
      --+|[&DieOutput]

  --:Stress Dice Block|
      --+[#990000]STRESS ROLLS[/#]|
      --?[$NumStressDice] -eq 0|>NA
      --?[$NumStressDice] -eq 0|EvaluationBlock
      --=DieCount|0
      --:StressLoop|
              -->RollStress|
              --=DieCount|[$DieCount] + 1
              --?[$DieCount] -lt [$NumStressDice]|StressLoop
  --:Output Stress Dice| but first append closing format tag
      --&StressOutput|+[/r]
      --+|[&StressOutput]

  --:EvaluationBlock|
      --+[#990000]EVALUATION[/#]|
     --:Output Success and Failure counts|
              --+|[r][b]Successes=[$NumSuccess][/b][/r]
              --+|[r][b]Failures=[$NumFail][/b][/r]
      --:Compare rolls|
              --=Diff|[$NumSuccess] - [$NumFail]
              --+|[r][b]Difference[$Diff][/b][/r]
      --+[#990000]RESULT[/#]|
      --:Output Overall Success or Failure|
              --?[$Diff] -gt 0|OverallSuccess
              --?[$Diff] -le 0|OverallFailure  
  --X| End macro
  
--:FUNCTIONS|
 --:NA|
    --+|[b][r]N/A[/r][/b]
    --<|
  --:RollBase|
    --=ThisRoll|[T#AlienD6]
    --?[$ThisRoll.tableEntryValue] -eq 6|>AddSuccess
    --&DieOutput|+[img width=32][$ThisRoll.tableEntryImgURL][/img]
    --<|
  --:RollStress|
    --=ThisRoll|[T#AlienStressD6]
    --?[$ThisRoll.tableEntryValue] -eq 6|>AddSuccess
    --?[$ThisRoll.tableEntryValue] -eq 1|>AddFail
    --&StressOutput|+[img width=32][$ThisRoll.tableEntryImgURL][/img]
    --<|
--:AddSuccess|
    --=NumSuccess|[$NumSuccess] + 1
    --<|
--:AddFail|
    --=NumFail|[$NumFail] + 1
    --<|
--:OverallSuccess|
    --+[c][#009900]~~~SUCCESS~~~[/#][/c]|
    --X|
    --<|
--:OverallFailure|
    --+[c][#ff0000]~~~FAILURE~~~[/#][/c]|
    --X|
}}

Author of script: David M.
Game/System specific? Which one: System Neutral
Does this script require additional mods to function? If yes, please list them here: N/A
Purpose of script: The following takes a collection of die rolls and sorts them for display purposes.
Description of intended results: Die rolls are sorted in ascending order.
Screenshots:
Caveats/ Notes: Currently hardcoded to 4 rolls, but could be generalized by adding loops, etc.
Script code:

 
!scriptcards {{  
  --=NumDice|4

  --=Roll1|1d6
  --=Roll2|1d6
  --=Roll3|1d6
  --=Roll4|1d6

  --+Unsorted Rolls|
  --+Rolls|[$Roll1] [$Roll2] [$Roll3] [$Roll4]

  --:PERFORM A BUBBLE SORT|
  --=i|0
  --=max_i|[$NumDice]-1
  --:OuterLoop|
        --=i|[$i]+1
                --=j|[$i]
                --:InnerLoop|
                    --=j|[$j]+1
                    --?[$Roll[$i.Raw]] -gt [$Roll[$j.Raw]] |>BubbleUp;[$i.Raw];[$j.Raw]
                --?[$j.Raw] -lt [$NumDice.Raw]|InnerLoop
        --?[$i.Raw] -lt [$max_i.Raw]|OuterLoop

  --+Rolls sorted ascending|
  --+Rolls|[$Roll1] [$Roll2] [$Roll3] [$Roll4]
  --X|

--:FUNCTIONS|  
  --:BubbleUp| accepts i, j as parameters. Swaps Roll[i] & Roll[j]
      --=Temp|[$Roll[%2%]]
      --=Roll[%2%]|[$Roll[%1%]]
      --=Roll[%1%]|[$Temp]
  --<|  
}}