Personal tools

Macros/Pathfinder Examples

From Roll20 Wiki

Jump to: navigation, search



To illustrate specific techniques for macros specifically designed for the Pathfinder RPG system and to demonstrate their use through examples. As you read through this article you will find certain techniques simplified or unused in order to emphasize the topic method. The examples provided are not necessarily meant to be used as-is(Though everything posted is functional). Rather, they're offered as an example of a particular method to be combined with other techniques for you to craft your own comprehensive macros using all techniques you're comfortable with employing.

This is a collaborative work with several contributors. Styles and methods will vary


Spacing: Spacing inside a roll rarely matters, as it does not generally affect the results of a roll. When making macros, spacing everything far apart will make it easier to see where you might have made an error, and to make it easier to adjust later on as needed.

When figuring out result spacing in the chat window, try to get things to fit on as few lines as possible. It makes for cleaner macros and speeds the game along if you can see and comprehend the results easily. Please also see the "Roll Templates" section towards the bottom of this article

Formating: Markdown language (like Reddit) is available to let you bold, italic, bold-italic, create a hyperlink, or include an image(not recommended for most macros, really)

* italics *
** bold **
*** bold italics ***
[link text](...html)

Group your Macros: To save your own screen space and to avoid having dozens of macro buttons, combine similar rolls into one macro: Ex: Conversation skills (bluff,sense motive, diplomacy, etc) can all be rolled at once in a single macro, rather than a macro button for each one.

Drop-Down Queries: These somewhat replace the Boolean Math queries below, but have other uses as well. A drop-down Query will present you a selection dialogue with several options, filling in the predefined content of what you selected.

Format ?{Prompt:|Label1, Result1 | Label2, Result2 | Label3, Result3} ...etc

Example [[1d8+3 + ?{Sneak Attack?:|Yes,3d6|No,0} ]]

Example2 hits for [[ ?{WeaponType:|Longsword, 1d8+3|ShortSword, 1d6+3| Dagger,1d4+1} ]] dmg

This can also be used extensively to create entire dictionaries of actions, list of all possible skill checks, entire spell books, etc. The one area drop-down queries run into problems(aside from their visual complexity) is when they contain other queries. The Syntax of the nested queries throws off the overall Drop-down query, so HTML Entities have to be used to replace the pipe " | ", comma, and " } " right curly brace characters anywhere WITHIN the overall drop-down query. A more detailed explanation of complex Drop-Down Roll Queries can be found here: [1]. There are some examples of complex drop-down queries further in this article.

Boolean Math: Using the Identity property of 1 and the multiplicative property of 0, combined with Queries, you can make ON / OFF type switches in your macros. This is as close as you can get to conditional statements in the Macro system. Real If/Then/Else requires a Pro subscription and the API. Note: Pathfinder almost always rounds down, so always use the "Floor" function to force it when finding the 1/2 of something. Example: (Two-Handed Weapon Damage)

[[ 1d12 + 5[STR] + ( ?{Two-Handed Weapon?|0}[TwoHanded?] * floor( 5[STR] * .5) ) ]]

Reason: Since regular weapon damage adds 1x your strength, and a Two-handed Weapon adds 1.5x your Strength you can add Query * HalfYourStrength. By using a 1 in your query result, you add the extra 1/2 str. If you reply 0, the added result is zero so effectively just your regular strength. Tidbit: Use * .5 instead of /2 in any programming or scripting system to avoid accidentally dividing by 0 or using the wrong Slash mark.

Extension: Roll20 gives you 3 token bars, but many people only use one - health. You can use bar2 and bar3 to store boolean values. I use bar2 to represent Power Attack. My L7 Fighter's attack roll looks like this:

/w gm Power Attack: [[@{selected|bar2}]]
/w gm Threatens at [[17 + 12 - 2*@{selected|bar2}]]

[[d20 + 12 - (2*@{selected|bar2})[Power Attack Penalty] ]] vs AC
[[2d6 + 6 + (6*@{selected|bar2})[Power Attack Bonus] ]] Normal Damage!
[[2d6]] Vital Strike Damage!

High and Low Tier: Using Boolean Math, you can create a switch that instantly changes *almost* all aspects of your table from low tier to high tier and back: (This assumes you use attributes to roll your attacks; see "Generic Attack Macro" in the "Macro Examples" section.) In this section I use (1-x) as "opposite of x", where x is a boolean value. 1-0=1, 1-1=0. (1-x) flips the boolean value.

To begin, set up a character, "Tier", with the following attribute:

High: 0

Now, in every macro, use boolean math to add in BOTH High and Low tier bonuses. For example:

/emas @{selected|token_name} attempts to avoid your attacks!
/desc [[d20 + (@{selected|fort})*(1-@{tier|high})[Low Tier Bonus] + (@{selected|fort-h})*(@{tier|high})[High Tier Bonus] ]] Fortitude
/desc [[d20 + (@{selected|ref})*(1-@{tier|high})[Low Tier Bonus] + (@{selected|ref-h})*(@{tier|high})[High Tier Bonus] ]] Reflex
/desc [[d20 + (@{selected|will})*(1-@{tier|high})[Low Tier Bonus] + (@{selected|will-h})*(@{tier|high})[High Tier Bonus] ]] Will

This can be done anywhere the same effect occurs with different numbers in high and low tier. I use it in EVERY macro.

When I create the table, on the splash screen I create a token on the GM layer. I link the token to "Tier", and I link Bar1 to "High". When the table makes and we determine tier, I set the value of Bar1 to 1 for high, 0 for low. (It's defaulted to 0 anyway.) Then everything (except HP) is automatically calculated with the appropriate value for the tier. For HP, I leave every token's Bar1 unlinked until they reach that encounter. (Otherwise I'll forget to change it.) With each encounter, I link Bar1 of each NPC to either HP or HP-H, depending on high or low.

Calculated Dice Roll: Mostly for Casters where damage of spells is often dependent on your level, you can use math and attributes to determine how many dice to roll. This is also an example of grouping rolls with { } and comparing them with KL1 (keep Lowest One) Example: CureLightWounds does 1d8 + CasterLevel, but only up to level 5 at max, giving us [[ 1d8 + ( { 5 , @{Level} }kl1) ]] This takes the raw number "5", compares it to your @{Level} attribute, and keeps the lower of the two. If you're level 2, you'll end up rolling 1d8+2. if you're level 12, you'll roll 1d8+5 Note: Grouped rolls like KL1 and Calculated Dice Roll's currently don't play nice with each other. The only way to combine them is to use nested Inline Rolls [[ [[]] ]]. For example, Fireball (CasterLevel of d6' up to 10d6) would come out as [[ [[ {10, @{CasterLevel} }kl1 ]]d6 ]] (Please note that there must not be any spaced between the ]] and d6

Passive Rolls for GMs: If you have your players keep Perception, Sense Motive, etc attributes defined in their character journals you can use @{Target|Attribute} or @{Selected|Attribute} to determine if the individual made their check without notifying the player that it happened. This assumes that the Tokens are bound to the Character Journal correctly.

/w GM @{Selected|Token_Name} Passive Perception [[ @{Selected|Perception} + 10]]

Since it's the GM whispering to the GM, only they will see the roll.

Corollary to Passive GM Roll: If your player-base is consistent, you can test all their passive checks at the same time and use it as a general macro for anything that might try to stealth, bluff, traps, etc. NOTE: Spacing gets a bit messy after 4 players without reworking it, as the Roll20 chat window only gives you 5 lines of text before posting your character name again. Example: (Secretly rolling generic monster's stealth check and comparing it to player's rolled perceptions)

/w GM NPC Stealth[[ (1d20 + ?{Stealth bonus?|0} ) ]]
/w GM Player's Name:[[ 1d20 + @{PlayerName1|Perception} ]]
/w GM Player's Name:[[ 1d20 + @{PlayerName2|Perception} ]]
/w GM Player's Name:[[ 1d20 + @{PlayerName3|Perception} ]]
/w GM Player's Name:[[ 1d20 + @{PlayerName4|Perception} ]]

Calculating Crits: Recently added Dice Rolling options now let you specify your crit range within the initial roll. 1d20cs>19 will display the result with a green critical highlight on a 19 or 20. 1d20cs>15, on a 15-20, etc.

Pathfinder Crits are your damage and most bonus' rolled multiple times, not the result multiplied. Since your original attack damage is already on the screen, only add one more damage roll for an x2 weapon, and two extra damage rolls for a 3x, etc.

/me stabs with his Keen LongSpear(19-20x3)!
Attack:[[1d20cs>19 + 6[AttackBonus] ]] for [[1d6 + 4[STR] ]] Dmg
C.Confirm:[[1d20 + 6[AttackBonus] ]]
Addt'l Crit Damage:[[ ( 1d6 + 4[STR] ) + ( 1d6 + 4[STR] ) ]]

Template NPCs and Players

Some use lots of attributes on my NPCs, and ask their players for a few as well. To keep from having to do the same work over and over, have a table titled "Template." On that template have three characters:


NPC has the following EMPTY attributes: (information in <> is descriptive of what I will fill in for each NPC in that box)

HP: <low tier hp> / <low tier hp max>
HP-H: <high tier hp> / <high tier hp max>
Fort: <fort save bonus>
Fort-H: <fort save high tier>
Ref: <Reflex save bonus>
Ref-H: <Reflex save high tier>
Will: <Will save bonus>
Will-H: <Will save high tier>
Attack1-Name: <Name of Attack1>
Attack1: <Attack1 Bonus Low Tier> / <Damage roll low tier>
Attack1-H: <Attack1 Bonus High Tier> / Damage roll high tier>
Attack1-Target: <AC, Touch, CMD, Automatic - Reflex for Half, etc.> / <die result that threatens OR DC of spell save>
Attack2-Name: <Name of Attack2>
Attack2: <Attack2 Bonus Low Tier> / <Damage roll low tier>
Attack2-H: <Attack2 Bonus High Tier> / Damage roll high tier>
Attack2-Target: <AC, Touch, CMD, Automatic - Reflex for Half, etc.> / <die result that threatens OR DC of spell save>
Attack3-Name: <Name of Attack3>
Attack3: <Attack3 Bonus Low Tier> / <Damage roll low tier>
Attack3-H: <Attack3 Bonus High Tier> / Damage roll high tier>
Attack3-Target: <AC, Touch, CMD, Automatic - Reflex for Half, etc.> / <die result that threatens OR DC of spell save>

Player has the following EMPTY attributes, as I will always ask for these:


Finally, the Tier character has ONE attribute:

High: <Boolean value - 1 for high tier, 0 for low tier>

The template table also includes my generic Attack1, Attack2, and Attack3 macros (in the macro examples section), a "Show-Attacks" macro (also in the macro examples section), and a "Roll-Saves" macro (macro examples section under "High/Low Tier")

When I'm prepping a new table, I don't start from a blank. I start by copying "Template." Then I count the NPCs and duplicate NPC that many times. Then I just fill in the information from the stat blocks. If a particular NPC has more than 3 actions, or I think it will need to do something nobody else will (concentration checks, for example) I'll create individual abilities for that NPC at that time. But other than that, my combat prep is basically done.

Rolling 0 for Untrained Skills

As we all know, some Pathfinder skill-checks can't be performed unless you have at least one Rank trained in that skill (Like Knowledges). Normally that provides an annoyance with macros, as we have to customize each one for each character's skills and abilities to make sure we only roll what that character knows. However, there's a trick you can use that will display a "0" instead of your roll, if your skill ranks are zero.

[[(1d20 + @{Knowledge-Arcana}) * ceil(@{Knowledge-Arcana-ranks}/100) ]]

This snipit uses the Pathfinder Character sheet, but can be used with any attribute that has the number of ranks listed separately from your actual total bonus.

In essence: 1d20+TotalBonus * NumberOfRanks/100, rounded up

If the Ranks = zero, your result will always be a zero. Due to the way rounding works in Roll20, any other value in Ranks will result in a "1".


Initiative: (the decimal point = your total init bonus. Used for breaking ties with enemies rolling the same, higher bonus wins). The &{tracker} part automatically adds the roll to the turn order. You *MUST* have your token selected for this macro to work correctly.

/me leaps into action! [[1d20 + 6.06 &{tracker}]]

Initiative (As an ABILITY on your character journal using Attributes instead. This can just be an attribute for the total initiative bonus and not bother with the math, but calculations can be useful) Note: The benefit of using the full calculation (dex + misc. init bonus) instead of just a flat value, is that it will dynamically update as your dex increases through Cat's Grace or other temporary effects. NOTE:: Due to wiki layout spacing, the macro is listed on multiple lines. It should be written as a single continuous line of text.

/me leaps into action! [[1d20 + @{DEX}[Dex] + @{InitBonus}[Traits] + ( @{DEX} + @{InitBonus} )*.01 
&{tracker}[TieBreaker] ]]

Defense - It's convenient to show all your defenses and make all saving throws in one click. Putting plain numbers inside [[ ]] is just for emphasis in the chat window.

/me defends himself from the assault!
CMD[[ 19 ]]
AC[[ 18 ]]|Flat[[ 18 ]]|Touch[[ 13 ]]
Fort[[ 1d20 + 3 ]]|Ref[[ 1d20 + 7 ]]|Will[[ 1d20 + 1 ]]
Concentration:[[ 1d20 + 11 ]]

Defense More complex using attributes and token bars, assuming HP and AC are tracked on token bars and it's currently selected). I use a token bar to track AC instead of an attribute because AC changes frequently in PF. The FlatFooted or Touch calculation may change with different class/feats/etc.

/me defends himself from the assault!
CMD:[[10[BASE] + @{BAB}[BAB] + @{STR}[STR] + @{Dex}[DEX] ]]
HP:[[ @{Selected|BAR3 ]] / [[ @{Selected|Bar3|MAX} ]]
AC[[ @{Selected|Bar1} ]]♦Flat[[ @{selected|Bar1} ]]Touch♦[[ 10 + @{DEX} ]]
Fort[[1d20 + @{Fort} ]]♦Ref[[1d20+@{Ref} ]]♦Will[[ 1d20+@{Will} ]]
Concentration:[[1d20 + 11]]
Evasion ♦ Uncanny Dodge

Generic Roll: A generic dice roll that asks for how many dice, what sided dice, and what modifiers you are adding to the roll. Mind the spacing around the d?, it matters here.

/me ?{Your Character is...?|does something}
[[ ?{Number of Dice|1}d?{Type of Die|6} + ?{Modifiers|0} ]]

Weapon 1 Mathematically speaking, power-attack should almost ALWAYS be used, so we don't often keep separate macros without it. Check out the section above on Boolean Math if you want to make an on/off flag for it. NOTE: Attack macros are the one place you definitely want to use a roll query for misc bonus'. It changes constantly in PF. NOTE2:: Due to wiki layout spacing, the first Attack and Confirm are on multiple lines. They should be written as a continuous line of text. The 1d20cs>19 makes the results highlight green on a 19-20 crit range.

/me grips his GreatSword firmly and swings Powerfully!
Attack:[[1d20cs>19 + 5[AttackBonus] -1[PowerAttack] + ?{Misc Bonus/Penalty?|0}[Misc. Bonus] ]] for [[2d6 + 6[STR*1.5] + 
3[PowerAttack] + ?{Damage Bonus?|0}[Damage Bonus] ]] Dmg
Confirm:[[1d20 + 5[AttackBonus] -1[PowerAttack] + ?{Misc Bonus/Penalty?|0}[Misc. Bonus] ]] for addt'l [[2d6 + 6[STR*1.5] + 
3[PowerAttack] + ?{Damage Bonus?|0}[Damage Bonus] ]]

MultiAttack: (Note: As you get high enough to make 3 or more attacks, you would likely rework it to query main or second attacks, re-arrange the fluff text for better spacing). The 1d20cs19 makes the results highlight green on a 19-20 crit range.

/me grips his GreatSword firmly and swings powerfully!
H1:[[1d20cs>19 + 5 -1[PowerAttack] + ?{Misc Bonus/Penalty?|0}[Misc. Bonus] ]] for [[2d6 + 6[STR*1.5] + 3[PowerAttack] + ?{Damage Bonus?|0}[Misc. Bonus] ]] Dmg
C1:[[1d20 + 5 -1[PowerAttack] + ?{Misc Bonus/Penalty?|0}[Misc. Bonus] ]] for addt'l [[2d6 + 6[STR*1.5] + [PowerAttack] + ?{Damage Bonus?|0}[Misc. Bonus] ]] Dmg
H2:[[1d20cs>19 + 5 -1[PowerAttack] -5 + ?{Misc Bonus/Penalty?|0}[Misc. Bonus] ]] for [[2d6 + 6[STR*1.5] + 3[PowerAttack] + ?{Damage Bonus?|0}[Misc. Bonus] ]] Dmg
C2:[[1d20 + 5 -1[PowerAttack] -5 + ?{Misc Bonus/Penalty?|0}[Misc. Bonus] ]] for addt'l [[2d6 + 6[STR*1.5] + 3[PowerAttack] + ?{Damage Bonus?|0}[Misc. Bonus] ]] Dmg

MultiAttack: (Using attributes and Queries. This should cover each attack and determines what the bonus' and penalties should be ) NOTE: Complex, but this covers weapon enchantments, misc bonus' such as Bless, and the -5/-10 penalties for your multiple attacks at higher levels. NOTE2: Due to wiki layout spacing, this appears on multiple lines. The macro itself would be continuous line.

/me grips his GreatSword firmly and swings powerfully!
Attack:[[1d20 + @{BAB}[BAB] + @{STR}[STR] + @{EnchantmentBonus} -3[PowerAttack] + ?{Misc Attack Bonus|0}[Misc Bonus]
 - ( (?{Main:0, Second:1, or Third:2 attack?|0})*5 )[BAB Penalties] ]] for [[2d6 + (floor(@{STR}*1.5))[1.5 STR] 
+ 9[PowerAttack] + ?{Misc Damage Bonus?|0} ]] Dmg

Rapid + MultiShot: This is a massive time/sanity saver for those who combine multishot and rapidshot. Also Monk Flurries. Note: Due to spacing, this is extremely bare-bones output and should be explained to the GM. It's VERY condensed to accommodate spacing. These should be fleshed out to use attributes, attack bonus queries, and other better techniques, but would detract from the example here. Sample Output: The !xx! are the crit confirm, and damage rolls.

Mark G. (GM): [Rapid/Multi]

Read left-to-right "Multishot attack MS rolled a 20, rolled a 17 to confirm any possible crits. Normal attack did 20 damage, if crit add an additional 21

Actual Macro: and yes, it can be difficult to read, but the output is clean! NOTE:: Due to wiki layout spacing, the first Hit1 is on multiple lines. It should be written as a continuous line of text.

/me draws his bow and peppers his enemies with arrows!
MS:[[1d20cs>19 + 15 -2]](![[1d20 + 15 -2]]!)=[[{ 1d8 + 3 , 1d8 + 3 }]]+![[{ 1d8 + 3 , 1d8 + 3, 1d8 + 3 ,1d8 + 3 }]]!
RS:[[1d20cs>19 + 15 -2]](![[1d20 + 15 -2]]!)=[[ 1d8 + 3 ]]+![[{ 1d8 + 3 , 1d8 + 3 }]]!
H2:[[1d20cs>19 + 10 -2]](![[1d20 + 10 -2]]!)=[[ 1d8 + 3 ]]+![[{ 1d8 + 3 , 1d8 + 3 }]]!
H3:[[1d20cs>19 + 5 -2]](![[1d20 + 5 -2]]!)=[[ 1d8 + 3 ]]+![[{ 1d8 + 3 , 1d8 + 3 }]]!

Stabilization Check: In PF, when you reach negative HP you have to roll a DC 10 Con check with penalties for the number of negative HP you have. If your negative HP exceeds your total CON, well... it's time to roll another character. Written as an Ability, assumes HP are tracked in Bar3 on your token, and you have an attribute named CON that has your bonus in the left field and max Con in the right field.

/me tries to convince himself the large hole in his chest is just a flesh wound...
DC 10 Con Check:[[ 1d20 + @{Con}[Con Mod] + @{Selected|Bar3}[Neg HP] ]]
On Fail: Take [[1]] Dmg.
If Neg HP([[ @{Selected|Bar3} * -1 ]]) = Con([[@{Selected|Con|Max} ]]) ... !! DEATH !!

Perception Basic macro; Perception is the most used skillcheck in the game

/me look around and listens carefully...
[Perception][[1d20 + 8 + ?{Favored Terrain/Other Bonus?|0} ]]

Knowledges: The extra blank line keeps them lined up nicely, usually not an issue unless you're a knowledge whore like Wizards.

/me considers the topic thoughtfully...

Linguistic[[ 1d20 + 7 ]] | Appraise[[1d20+10]]
Arcana[[ 1d20 + 15 ]] | Nature[[1d20 + 10]]
Planes[[1d20 + 11]] | Religion[[ 1d20 + 11 ]]
Dungeon[[ 1d20 + 9 ]] | Nobility[[1d20 + 7]]
Engineer[[ 1d20 + 7 ]] | History[[1d20 + 7 +2]]

Athletics: Generally any skillcheck representing a movement action

/me rolls his shoulders and prepares for a feat of ATHLETICS!
Acrobatics:[[1d20 + 10]]
Jump:[[1d20+3]] Climb:[[1d20+8]]
Swim:[[1d20+7]] Ride:[[1d20+3]]
Fly: [[1d20 -1]]

Sneaky: Various rogue-type actions

/me indulges in a bit of legerdemain and skulduggery...
Disable Device: [[ 1d20 + 12 ]]
Sleight of Hand:[[ 1d20 + 7]]
Disguise: [[1d20 + 4]]]
Stealth:[[ 1d20 + 12 ]]

Conversation: Basic Conversation skills

/me tries to remember long-lost conversation skills...
Bluff/*Feint*: [[1d20 + 6]]
Diplomacy:[[1d20 -3 ]]
Intimidate:[[1d20 + 4]]
Sense Motive:[[1d20 + 7]]

Concentration Using drop-down queries that will roll your Concentration Check and prompt for which situation you're rolling against and display the appropriate DC to beat.

&{template:pf_generic} {{name=Concentration: [[1d20cs>1cf<20 + @{Concentration}]] }} {{ ?{Concentration type?
|Casting Defensively, DC [[ 15 + (2 * ?&#123;Spell Level?&#125;)[SL] ]]=Casting Defensively
|Injured while casting, DC [[ 10 + ?&#123;Damage Taken?&#125;[DMG] + ?&#123;Spell Level?
&#125;[SL] ]]=Injured while casting
|Continuous damage, DC [[ 10 + floor(0.5 * ?&#123;damage dealt?&#125;)[DMG] + ?&#123;Spell Level?&#125;[SL] ]]=Continuous damage
|Affected by a non-damaging spell, DC [[ ?&#123;DC of the affecting spell?&#125;[DC] + ?&#123;Spell Level?&#125;[SL] ]]=Affected by a non-damaging spell
|Grappled or pinned, DC [[ 10 + ?&#123;grappler's CMB?&#125;[CMB] + ?&#123;Spell Level?&#125;[SL] ]]=Grappled or pinned
|Entangled while casting, DC [[ 15 + ?&#123;Spell Level?&#125;[SL] ]]=Entangled while casting
|Vigorous motion, DC [[ 10 + ?&#123;Spell Level?&#125;[SL] ]]=Vigorous motion
|Violent motion, DC [[ 15 + ?&#123;Spell Level?&#125;[SL] ]]=Violent motion
|Extremely violent motion, DC [[ 20 + ?&#123;Spell Level?&#125;[SL] ]]=Extremely violent motion
|Wind with rain or sleet, DC [[ 5 + ?&#123;Spell Level?&#125;[SL] ]]=Wind with rain or sleet
|Wind with hail and debris, DC [[ 10 + ?&#123;Spell Level?&#125;[SL] ]]=Wind with hail and debris
|Weather caused by spell, (*see spell*)=Weather caused by spell} }}

Color spray: Complicated spells that also include rolls are excellent for a macro. Avoid transcribing entire spell descriptions though.

/me raises his hands and links his thumbs before a cone of scintillating color erupts from his palms!
[Color Spray]
DC[[14]] Will Neg | SR:[[1d20 + 7]]
2 HD: Unconscious, blinded, stunned [[2d4]] rounds then blinded and stunned 
[[1d4]] rounds, then stunned [[1]] round.
3 or 4 HD:Blinded,stunned [[1d4]] rounds, then stunned [[1]] round
5 or more HD: stunned for [[1]] round.

Grease: Simplest form without anything fancy. Most appropriate for one-shots

/me cups his palm as though he were standing on a mound in a field and chants the verbal component "Uncto"!
DC[[14]] Ref Neg | SR:No
[[10]]ft. radius or single object for [[2]] minutes

Flaming Sphere: Example of fleshing out all the rolls so you don't have to touch the macro itself again, just attributes on your sheet)

/me gestures as though he was molding a small sphere in his hands and utters, "Flamma Globus"!
[Flaming Sphere]
DC[[ 10[Base] + 2[SpellLevel] + @{Int}[INT] ]] Ref Neg | SR:[[ 1d20 + @{Level}[Level] ]]
Dur:[[ @{Level}[Level] ]] Rd. Rng:[[100 + { @{Gol|Level} * 10 } ]]ft.
Burning Sphere uses caster's move to shift 30ft each round, co-occupying a 5-ft. 
area. Any creature in this area suffers [[3d6]] fire damage.

Mad Monkeys: Assuming augmented summoning. Macros are great for summons and repeat effects

/me scratches, hopping on one leg, strangely ape-like phrases escaping his lips as he chants...
Melee[[2d6]] + DC[[16]] Fort: Nauseated and Deafened [[1]]rd.
Free Act:Disarm/Steal[[ 1d20 + 7[Level] + 5[CHR] ]] vs. CMD

Black Tentacles:

/me closes his eyes while chanting, channeling the horror of Japanese school girls throughout the ages..
Area[[20]]ft Radius|SR:No
On caster turn or enter area:
Grapple[[1d20+7[Level]+4[STR]+1[Size] ]] & [[1d6+4[STR] ]] dmg/rd
CMD to escape[[10[BaseCMD]+7[Level]+4[STR]+1[Size] +5[Bonus]]]
Tentacles Cannot be Damaged, only dispelled


/me raises his hands and tosses a handful of glittering dust into the air while canting, "Coruscantes Et Cinere"!
DC:[[10[BASE] + 2[SL] + @{Gol|GolInt}[Int] +1[SF] ]]Will Neg | SR:No
Dur:[[ @{Level} ]] rds | Rng[[100 + (10*@{Level} ) ]]ft
[[10]]ft. radius, targets blinded and invisible creatures revealed, stealth receive -40 penalty.
Blinded creatures may attempt to save at the end of their turns.

Alchemical Flask When bombs and splash weapons miss, you roll for where it actually lands.

/me pulls the pin and counts to 5... NO! I mean 3!!
Hit:[[1d20+5]] for [[1d6+3]]dmg.
Adj. take [[1]] dmg
If Miss, it lands at [[1d8]]
[[4]] | [[5]] | [[6]]
[[3]] | X | [[7]]
[[2]] | [[1]] | [[8]]

Generic Attack Macros that work for ALL of your NPCs
Assumes NPCs all copied from a template (or manually created but why?) that contains Attributes:

Attack1: <attack bonus - 0 for automatic hits with saves> / <damage roll>
Attack1-Target: <AC, Touch, CMD, Reflex Negates, etc.> / <Minimum Threat OR Save DC>
Attack1-Name: <Name of Attack>
(Attack2, Attack3 similarly)

As for the macro, I like to keep it in the Macros box, NOT in the abilities box. If something needs tweaking, I can go to ONE place and tweak it for ALL NPC's instead of to EACH character sheet.

/emas @{selected|token_name} attacks @{target|token_name} with its @{selected|Attack1-Name}!
/w gm [[@{selected|Attack1-Target|Max} + @{selected|Attack1}]] to threaten/save
/desc [[d20 + @{selected|Attack1}]] vs @{selected|Attack1-Target}]]
/desc [[@selected|Attack1|Max}]] damage!

Works for spells and attacks. If a spell requires a touch attack AND a save, modify Attack1-Target|Max to be the difference between the DC and the attack bonus, so that when added they will accurately display the DC.

Useful along with this:

/w gm Attacks for @{selected|token_name}
/w gm Attack1: @{selected|Attack1-name}
/w gm Attack2: @{selected|Attack2-name}
/w gm Attack3: @{selected|Attack3-name}


With the advent of Roll Templates, formatting options for Macros have a lot more options than before. The more complex (and let's be honest, "Clean", looking Templates are specific to the Character Sheet you're using. However, there is also a "Default" Template that can be used with any game, regardless of Character Sheet.

NOTE: In many cases, the Default Template results in much cleaner macros. However the more tightly spaced macros tend to suffer due to alignment and spacing limitations inherent to the Default Template format. ANY Macro created as a Roll Template will need some fiddling to get the spacing to look nice.

General Usage: To use the Default Template, start off with regular Macro or Ability creation.

The basic format is:

&{template:default} {{name=Header Bar Text}} {{LeftColumnContent=RightColumnContent}}

Note: When using Roll Templates, you must keep everyone on one line of text. This includes any macros or procs that you might call from within the macro.

 &{template:default} {{name=Perception}} {{Perception:=[[1d20 + 2 ]]}} 

Every curly brace pair {{ }} you add, adds another Row to the template's output in chat. The = symbol is was defines LeftColumn|RightColumn. If you leave it out entirely, each {{ }} pair will use the entire row. If even one = is used within your macro, columns will be created.

A note about MarkDown language formatting:

Since there is built-in formatting in the Default Template, we have to make extensive use of the MarkDown language formatting marks.
* italics *
** bold **
*** bold italics ***

Roll Template Examples:

Note: These examples are displayed with line breaks for readability. They must be entered as one contiguous line of text to function correctly

(Melee Weapon)

&{template:default} {{name=Melee Attack}} 
{{Hit:=[[1d20cs>17 + 5[STR] + 10[BAB] +3[WeaponBonus] + ?{AttackMod|0} ]]}} 
{{Dmg:=[[1d8 + 5[STR] + 3[WeaponBonus] + ?{DamageMod|0} ]]}} 
{{Confirm:=[[1d20 +4[CritFocus] + 5[STR] + 10[BAB] +3[WeaponBonus] + ?{AttackMod|0} ]]}} 
{{CritDmg:=[[1d8 + 5[STR] + 3[WeaponBonus] + ?{DamageMod|0} ]]}} 
{{Note:=**Crits** cause **[Nauseated](**}} 


&{template:default} {{name=Knowledges}} 
{{Arcana[[ 1d20 + 20 ]]=**Appraise**[[1d20 + 10]]}} 
{{Linguistic[[ 1d20 + 7 +5]]=**Nature**[[1d20 + 15 +1[Book]]]}} 
{{Planes[[1d20 + 18 ]]=**Religion**[[ 1d20 + 11 ]] }} 
{{Dungeon[[ 1d20 + 7 ]]=**Nobility**[[1d20 + 7 ]]}} 
{{Engineer[[ 1d20 + 7 ]]=**History**[[1d20 + 18 +2[Book] ]]}} 
{{Geography[[ 1d20 + 11 ]]=**Local**[[1d20 + 11 ]]}}

(Conversation) Note how I have two template calls here. Because the first one uses "=" to make columns, the language list would have been squished.

&{template:default} {{name=Conversation}} 
{{Bluff[[ 1d20 + 10 ]]=**Diplo**[[ 1d20 + -1 ]]}} 
{{Sense Motive[[ 1d20 + 2 ]]=**Intim**[[ 1d20 + -1 ]] }}
&{template:default} {{name=Languages}} 
{{*Common, Elven, Read-Lips }}


When using the "PATHFINDER" character sheet in a campaign, you gain access to the Roll Templates associated with it. This opens up more formatting options and tricks to throw in your bag of holding. The PATHFINDER sheet itself has vastly improved in recent months, so it's entirely usable on its own, but some folks like to have more control over their rolls. This section will provide some examples of PF sheet macros, but won't go into detail on the sheet's mechanics as they change frequently. Please see the actual sheet itself for the syntax and Roll Template Info(Gear icon, Roll Template Info drop-down)

Unless otherwise noted; these examples do NOT use the sheet's values. There will be another section below this that offers example macros that use the sheet directly.

As always, these should be entered as a single continuous line of text. They are broken up for display purposes in this wiki.

Game Notice: Just a simple note in chat to emphasize something about the Campaign like leveling, important quest notes, reminders of what needs to be done next session, etc

&{template:pf_attack} {{name=✪ *Quest / Game Note* ✪}}  {{?{Game Notice:}}}

Math is Hard: For those, like myself, who have some challenges with mental maths

&{template:pf_attack} {{name=✪ Math is Hard ✪}} {{**Result:** [[ ?{Maths} ]]}}


&{template:pf_generic} {{name=Perch Initiative: [[1d20 + @{MYINIT}[Initiative Bonus] + 
( (@{MYINIT}) *.01)[TieBreaker]  &{tracker} ]]}} 

Defense: lists HP, saves, resistances, etc. The ♡ are just AltCode replacements. You can copy/paste.

&{template:pf_attack} {{name=Gellius Defense ♡@{Gellius|MyHP}/@{Gellius|MyHP|Max}♡  }} 
{{AC[[@{MyAC} ]] Fl[[ @{MyFlatAC} ]] Tch[[ @{MyTouchAC} ]] CMD[[@{MyCMD} ]] }} 
{{Fort[[1d20 + @{MyFort} ]] Reflex[[1d20 + @{MyRef} ]] Will[[1d20 + @{MyWill} ]] }} 
{{*Resist Electricity* **-**[[5]] }} {{*Insight vs Spells* **+**[[2 + floor(@{MyLevel} /5)  ]] }}

Saving Throws: asks in a drop-down which save to make, then prints only one.

&{template:pf_defense} {{character_name=My Fighter}} {{name=Saving Throws}}
{{?{Saving Throw|Fortitude,Fortitude=[[d20+@{fort} ]]|Reflex,Reflex=[[d20+@{ref} ]]|Will,Will=[[d20+@{will} ]]}}}


&{template:pf_attack} {{name=@{selected|Token_Name} Perception}}{{Perception:  [[1d20 + @{MyPerception}  ]] }}

UMD: rolls your UMD check in the titlebar and uses the body of the template for the check table

&{template:pf_attack} {{name=Gellius UMD Check: [[1d20 + @{MYUMD}]] }} 
{{**25**=Activate Blindly}}{{**25 + Sp Lvl**=Decipher Scroll}}{{**20 + CL**=Use Scroll}}
{{**20**=Use wand / Emulate class}}{{**25** =Emulate Race}}{{**30**=Emulate Align}}

Conversation: I'm a fan of AltCodes to add emphasis. The ◄ ► can just by copy/pasted or left out

&{template:pf_attack} {{name=Gellius: Conversation}} {{Bluff[[ 1d20 + @{MyBluff}  ]]=
Diplo[[ 1d20 + @{MyDiplo}  ]]}} {{Sense[[ 1d20 + @{MySense}  ]]=Intim[[ 1d20 + @{MyIntim}  ]] }}
{{*◄Auran► ◄Draconic► ◄ Dwarven►*=*◄Elven► ◄Halfling► ◄Infernal► ◄ReadLips►* }}


&{template:pf_attack} {{name=Gellius: Athletics}} {{[[ 1d20 + @{MyJump}  ]] Jump= 
Acrobatics [[1d20 + @{MyAcrobatics}  ]]}} {{[[ 1d20 +@{MySwim}  ]] Swim=Climb [[ 1d20 + @{MyClimb}  ]]}}
{{[[1d20 + @{MyFly}]] Fly=Ride [[ 1d20 + @{MyRide}  ]]}}

Knowledge: I've found that when using large lists of output and rolls, it lines up nicer if you keep the rolls to the "outside" of the "=" sign, and keep the labels "inside".

&{template:pf_attack}{{name=Gellius: Knowledges}}
{{[[1d20 + @{MyArcana}]] Arcana=Nature [[1d20 + @{MyNature} ]] }} 
{{[[1d20 + @{MyPlanes}]] Planes=Religion [[1d20 + @{MyReligion}]]}} 
{{[[1d20 + @{MyDungoneering}]] Dungeon=Geography [[1d20 + @{MyGeography}]]}} 
{{[[1d20 + @{MyAppraise} ]] Appraise=Engineer [[1d20 + @{MyEngineering}]]}} 
{{[[1d20 + @{MyHistory} ]] History=Linguistics [[1d20 + @{MyLinguistics} ]]}} 
{{[[1d20 + @{MyNobility}  ]] Nobility=Local [[1d20 + @{MyLocal} ]]}}  
{{[[1d20 + @{MyHeal}  ]] Heal=Survival [[1d20 + @{MySurvival} ]]}}

Cure Light Wounds: standard healing spell, limited to 1d8+5

&{template:pf_attack} {{name=Cure Light Wounds}} {{ @{Target|Token_Name} regains [[1d8+ {5, @{MyLevel} }kh1 ]] HP }}

Cure Wand: Prompts for how many charges to use and displays accordingly

&{template:pf_attack} {{name=Wand:Cure Light Wounds}}{{Target=@{target|Token_Name}}}
{{Charges:[[?{How many charges|1}]] =Heal [[?{How many charges|1}d8 + ?{How many charges|1}  ]] HP}}

MissChances: Averting Gaze, Concealment, and Mirror Images miss chances and hit/miss results

&{template:pf_attack} {{name=Miss Chances [1=Hit,0=Miss]}}{{Avert Gaze=50%[[1d100cs0cf0>50]] }}
{{Mirror Image= [[ 1d(1+?{Qty of Mirror Images? ( 0 if None )|0})cs0cf0<1 ]]}}

Splash Miss: Thrown splash weapons' random square roll on a miss

&{template:pf_attack} {{name=Splash Weapon Miss}} {{**Lands at [[1d8]] from** ***' XX '*** }} 
{{[[4]] ♦ [[5]] ♦ [[6]]}} {{ [[3]] ♦ **XX** ♦ [[7]] }} {{[[2]] ♦ [[1]] ♦ [[8]] }}

Coup-de-Grace save: Fort Save to survive a coup de grace

&{template:pf_attack} {{name=Coup De Grace: Defense}}  
{{ Fort Save: [[1d20+@{MyFort}]] =vs DC [[10 + ?{Damage Dealth?|0}   ]]  }}

Stabilize: Stabilize check when below 0 HP

&{template:pf_attack} {{name=@{selected|Token_Name} Stabilize: 
{{Con Check:=[[ 1d20 + @{Maudril|MyCon} + @{Selected|Bar1} ]] vs DC:10 }} 
{{On Fail:= Take [[1]] Dmg}}{{If Neg HP [[ 0+@{Selected|Bar1} ]] ≥ 
[[ @{Maudril|MyCon|Max} ]]=**† PERMA † 💀DEATH💀**}}

Confusion Spell check ( To use PF Sheet STR mod, use "[[1d8+[[@{Str-Mod}]][STR] ]]" instead of 1d8+1 )

&{template:pf_attack} {{name=Confusion Check: [[1d100cf0cs0]] }}
{{**01-25**=Acts Normally}}{{**26-50**=Does Nothing but Babble incoherently}}
{{**51-75**=[[ 1d8 + 1[STR] ]] to self}} {{**76-100**=Attack Nearest Creature}}

Sneak Attack: PF Unchained Rogue's Sneak Attack effects

&{template:pf_attack} {{name=Sneak Attack:  @{MYSNEAKATTACK}d6 }}
{{*SneakAttack*=[[@{MYSNEAKATTACK}d6]]}} {{+ [[ @{MYSNEAKATTACK}d1cf1cs2]] Bleed=**- **2 AC & Attack**  }}
{{vs. Rogue=**- **6 AC & Attack** }}

Concealment / Miss Chance Check(rolls our chances to hit/miss given concealment like blur, averting gaze, BlindFight, and Mirror Images)

&{template:pf_attack}} {{name=Miss Chances}}{{subtitle= [ 1=Hit , 0=Miss ]}}{{Blur=20%[[1d100cs0cf0>21]] }}{{Avert Gaze=50%[[1d100cs0cf0>50]] }}{{BlindFight=20%[[{1d100cs0cf0,1d100cs0cf0}kh1>21]]
50%[[{1d100cs0cf0,1d100cs0cf0}kh1>51]]}}{{Mirror Image= [[ 1d(1+?{Qty of Mirror Images? ( 0 if None )|0})cs0cf0<1 ]]}}


Between the sheet's improvements, the recent updates that allow nested inline rolls, and general improvements overall, it's now a lot more viable to reference the sheet directly. There are always one-off abilities, spells, or other unique Macros needed that the sheets don't natively account for, though. These examples should serve to illustrate how to reference some of these values in a clean way.

Generally (but not always) you can hover your mouse over the greyed out fields in the PF sheet to see what variable name they can be referenced by. Calculated fields can sometimes be a nasty mess to hover over in the output. If that's the case, enclose the variable called in its own [[ ]]. These nested brackets will make it just show the final result of the roll in the output, instead.

Roll First Attack from sheet(Calls the first defined Attack weapon from the sheet's "Attacks" tab)


Longbow: calls a slight modification of the second repeating weapon defined in the ATTACK tab

&{template:pf_attack}  {{subtitle}} {{name=@{repeating_weapon_$2_name}}} 
{{attack=[[ 1d20cs>[[ @{repeating_weapon_$2_crit-target} ]] + [[ @{repeating_weapon_$2_total-attack} ]] 
+ ?{Misc. Attack Bonus|0} ]] vs AC}} 
{{crit_confirm=[[ 1d20 + [[ @{repeating_weapon_$2_total-attack} ]] + ?{Misc. Attack Bonus|0} ]] vs AC}} 
{{damage=[[ @{repeating_weapon_$2_damage-dice-num}d@{repeating_weapon_$2_damage-die} + 
[[ @{repeating_weapon_$2_total-damage} ]] ]]}}  
{{crit_damage= [[ [[ (@{repeating_weapon_$2_damage-dice-num} * (@{repeating_weapon_$2_crit-multiplier} 
- 1)) ]]d@{repeating_weapon_$2_damage-die} + [[ (@{repeating_weapon_$2_total-damage} * 
(@{repeating_weapon_$2_crit-multiplier} - 1)) ]] ]]}} 
{{type=@{repeating_weapon_$2_type}}} {{description=@{repeating_weapon_$2_notes}}} 

EarthBreaker Attacks A very specific Drop-down query for a two-handed weapon that lets you select a single Attack of Opportunity, Full Round, Vital Strike, and versions of the same under the Enlarge Person spell. (damage dice of the weapon has to be updated for your particular weapon type, and assumes weapon focus, Power attack, a +1 weapon, and a 4x Crit. Auto-Ajusts attack/dmg bonus from the BUFFS section of the Pathfinder Character Sheet)

Copy/Paste as-is

&{template:pf_attack} {{color=blue}} ?{Attack Type:
| Vital Strike, {{name=VitalStrike EarthBreaker +1 &#125;&#125; {{attack=[[1d20 + @{attk-melee} + 3[F.FOCUS] + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{damage=[[4d6 + [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total} + ?{Misc.Damage&#124;0&#125;[MISC]  ]] &#125;&#125; {{crit_confirm=[[1d20 + @{attk-melee}  + 3[F.FOCUS]+ 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{crit_damage= [[4d6 + 2*( [[floor(1.5*@{STR-MOD})]][STR] +1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]) ]] &#125;&#125;
| Vital Strike(Enlg), {{name=VitalStrike(Enlg) EarthBreaker +1 &#125;&#125; {{attack=[[1d20 + @{attk-melee} + 3[F.FOCUS] + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{damage=[[6d6 + [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total} + ?{Misc.Damage&#124;0&#125;[MISC]  ]] &#125;&#125; {{crit_confirm=[[1d20 + @{attk-melee}  + 3[F.FOCUS]+ 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{crit_damage= [[6d6 + 2*( [[floor(1.5*@{STR-MOD})]][STR] +1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]) ]] &#125;&#125;
| Full-Round, {{name=FullRound EarthBreaker +1 &#125;&#125; {{attack=[[1d20 + @{attk-melee} + 3[F.FOCUS] + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{damage=[[2d6 + [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]  ]] &#125;&#125; {{crit_confirm=[[1d20 + @{attk-melee}  +3[F.FOCUS]+ 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{crit_damage= [[4d6 + 2*( [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]) ]] &#125;&#125;{{attack2=[[1d20 + @{attk-melee}-5 + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{damage2=[[2d6 + [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]  ]] &#125;&#125; {{crit_confirm2=[[1d20 + @{attk-melee}-5 + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{crit_damage2= [[4d6 + 2*( [[floor(1.5*@{STR-MOD})]][STR] +1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]) ]] &#125;&#125;
| Full-Round(Enlg), {{name=FullRound(Enlg) EarthBreaker +1 &#125;&#125; {{attack=[[1d20 + @{attk-melee} + 3[F.FOCUS] + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{damage=[[3d6 + [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]  ]] &#125;&#125; {{crit_confirm=[[1d20 + @{attk-melee}  + 3[F.FOCUS]+ 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{crit_damage= [[6d6 + 2*( [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]) ]] &#125;&#125;{{attack2=[[1d20 + @{attk-melee}-5 + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{damage2=[[2d6 + [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]  ]] &#125;&#125; {{crit_confirm2=[[1d20 + @{attk-melee}-5 + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{crit_damage2= [[6d6 + 2*( [[floor(1.5*@{STR-MOD})]][STR] +1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]) ]] &#125;&#125;
| Attack of Opportunity, {{name=AoO EarthBreaker +1 &#125;&#125; {{attack=[[1d20 + @{attk-melee} + 3[F.FOCUS] + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{damage=[[2d6 + [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]  ]] &#125;&#125; {{crit_confirm=[[1d20 + @{attk-melee}  +3[F.FOCUS]+ 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{crit_damage= [[4d6 + 2*( [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]) ]] &#125;&#125;
| Attack of Opportunity(Enlg), {{name=AoO(Enlg) EarthBreaker +1 &#125;&#125; {{attack=[[1d20 + @{attk-melee} + 3[F.FOCUS] + 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{damage=[[3d6 + [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]  ]] &#125;&#125; {{crit_confirm=[[1d20 + @{attk-melee}  + 3[F.FOCUS]+ 1[ENCHANT] + ?{Misc.Attack&#124;0&#125;[MISC] ]] vs AC &#125;&#125; {{crit_damage= [[6d6 + 2*( [[floor(1.5*@{STR-MOD})]][STR] + 1[ENCHANT] + @{buff_DMG-total}[BUFFS] + ?{Misc.Damage&#124;0&#125;[MISC]) ]] &#125;&#125;

Init: Copy As/Is

&{template:pf_generic} {{name=Initiative: [[ (1d20 + [[ @{init} ]][init] + [[ abs(0.01 * @{init}) ]][tie-breaker]) &{tracker} ]]}}

Defenses: (You have to update the character name "HawkEye" for max HP to work with your character in this example) You need to enter this as one long line of text, not as-is.

&{template:pf_attack} {{name=♡♡ [[@{HP}[CurrentHP] ]] / [[@{Hawkeye|HP|Max}[MaxHP] ]] ♡♡}} 
{{**CMD:**[[@{CMD}]] • **FF-CMD:**[[@{FF-CMD}]] }} {{**AC:**[[ @{AC} ]] • **Flat:**[[ @{Flat-Footed} ]] 
• **Tch:**[[ @{Touch} ]] }}{{ **Fort:**[[1d20 + @{Fort} ]] • **Ref:**[[ 1d20+@{Ref} ]] • 
**Will:**[[ 1d20+@{Will} ]] }}

Defenses: (Drop-DOwn Version) (Gives a drop-down option for physical defense, saving throws, Ability Checks, Confusion spell check, Coup De Gras saves, and Stabilize checks)

Copy/Paste As-Is without changes.

&{template:pf_generic}  {{color=darkblue}}{{name=@{selected|token_name} ?{Select The Defense Type
| Physical, Defense &#9825;@{selected|bar1}&#124;@{selected|bar1|max}&#9825; &#125;&#125; {{AC[[ @{ac} ]] Flat[[ @{flat-footed} ]] Touch[[ @{Touch} ]] CMD[[@{CMD} ]]
| Saving Throw, Saves &#9825;@{selected|bar1}&#124;@{selected|bar1|max}&#9825; &#125;&#125; {{Fort[[1d20 + @{Fort} ]]  Reflex[[1d20 + @{Ref} ]]  Will[[1d20 + @{Will} ]] &#125;&#125;{{**vs Enchantments +[[2]] **&#125;&#125;  {{**Immune Sleep**
| Attribute Save, Attributes &#9825;@{selected|bar1}&#124;@{selected|bar1|max}&#9825; &#125;&#125; {{STR[[ 1d20+@{str-mod} ]] DEX[[ 1d20+@{dex-mod} ]]  CON[[ 1d20+@{con-mod} ]] &#125;&#125; {{INT[[ 1d20+@{int-mod} ]] WIS[[ 1d20+@{wis-mod} ]] CHA[[ 1d20+@{cha-mod} ]]
| Confusion Check, Confusion &#9825;@{selected|bar1}&#124;@{selected|bar1|max}&#9825; &#125;&#125; {{[[1d100cf0cs0]] &#125;&#125;{{**01-25**=Acts Normally&#125;&#125;{{**26-50**=Does Nothing but Babble incoherently&#125;&#125;{{**51-75**=[[1d8+@{str-mod}]] to self&#125;&#125; {{**76-100**=Attack Nearest Creature
| Coup De Gras, Coup Save &#9825;@{selected|bar1}&#124;@{selected|bar1|max}&#9825; &#125;&#125; {{Fort Save: [[1d20+@{Fort}]] =vs DC [[10 + ?&#123;Damage Dealt?&#124;0&#125; ]] 
| Stabilize, Stabilize &#9825;@{selected|bar1}&#124;@{selected|bar1|max}&#9825; &#125;&#125; {{Con Check:=[[ 1d20 + @{CON-Mod}[Con Mod] + @{Selected|Bar1} ]] ***DC:10*** &#125;&#125; &#123;&#123;On Fail:=*[[1]] Dmg* &#125;&#125; &#123;&#123;If Neg  HP [[ 0+@{Selected|Bar1} ]]  =**≥** [[ @{Con} ]]&#125;&#125; &#123;&#123;***♰ PERMA ♰***=***💀 DEATH 💀 *** 
} }}

Stabilize: Very straight forward Stailization check referencing your sheet's Con-Mod, total Con, and token's BAR1 for current HP.

Edit to be one long line of text, not as-is.

{{name=@{selected|Token_Name} Stabilize: *[Link](*}} 
{{Con Check:=[[ 1d20 + @{Con-mod}[Con Mod] + @{Selected|Bar1}[NegHP] ]] vs DC:10 }} 
{{On Fail:= Take [[1]] Dmg}}
{{If Neg HP [[ @{Selected|Bar1}[NegHP] ]] ≥ [[ @{Con}[Con Score] ]]=**† PERMA † 💀DEATH💀**}}

Skill Checks(Alternate)Provides a drop-down for ALL skill checks, and reports a "0" for any untrained skills that require training, like Knowledges. Comprehensive.

Copy/paste as-is

&{template:pf_attack} {{name=?{Skill Grouping 
| Athletics, @{selected|token_name} Athletics Check&#125;&#125; {{[[1d20 + @{ACROBATICS}  ]] Jump=Acro [[1d20 + @{ACROBATICS}  ]] &#125;&#125; {{[[1d20 + @{CLIMB} ]] Climb=Swim [[1d20 + @{SWIM} ]]&#125;&#125;  {{[[ 1d20 + @{RIDE} ]] Ride=Fly [[1d20 + @{FLY}]]  
| Conversation/Interaction, @{selected|token_name} Conversations&#125;&#125; {{[[1d20cs0cf0 + @{INTIMIDATE} ]] Intim=Diplo [[1d20cs0cf0 + @{DIPLOMACY} ]]&#125;&#125; {{[[1d20cs0cf0 + @{SENSE-MOTIVE} ]] Sense=Bluff [[1d20cs0cf0 + @{BLUFF} ]]&#125;&#125; {{ [[ (1d20cs0cf0+@{handle-animal}) * ceil(@{handle-animal-ranks}/100)]] Handle Animal =  Performance[[1d20cs0cf0 + @{perform}]]
| Knowledge, @{selected|token_name} Knowledges&#125;&#125; {{[[(1d20 + @{Knowledge-Arcana}) * ceil(@{Knowledge-Arcana-ranks}/100) ]]Arcana=Nature[[(1d20 + @{Knowledge-Nature}) * ceil(@{Knowledge-Nature-ranks}/100) ]] &#125;&#125;  {{[[(1d20 + @{Knowledge-Planes}) * ceil(@{Knowledge-Planes-ranks}/100) ]]Planes=Religion[[(1d20 + @{Knowledge-Religion}) * ceil(@{Knowledge-Religion-ranks}/100) ]]&#125;&#125; {{[[(1d20 + @{Knowledge-dungeoneering}) * ceil(@{Knowledge-dungeoneering-ranks}/100) ]]Dungeon=Geography[[(1d20 + @{Knowledge-Geography}) * ceil(@{Knowledge-Geography-ranks}/100) ]]&#125;&#125;  {{[[1d20 + @{Appraise}]]Appraise=Engineer[[(1d20 + @{Knowledge-Engineering}) * ceil(@{Knowledge-engineering-ranks}/100) ]]&#125;&#125;  {{[[(1d20 + @{Knowledge-History}) * ceil(@{Knowledge-History-ranks}/100) ]]History=Linguistics[[(1d20 + @{Linguistics}) * ceil(@{Linguistics-ranks}/100) ]]&#125;&#125;  {{[[(1d20 + @{Knowledge-Local}) * ceil(@{Knowledge-local-ranks}/100) ]]Local=Nobility[[(1d20 + @{Knowledge-Nobility}) * ceil(@{Knowledge-Nobility-ranks}/100) ]]&#125;&#125; {{[[1d20cs0cf0+@{Heal}]] Heal = Craft[[1d20cf0cs0+@{craft}]]
| Senses, @{selected|token_name} Senses&#125;&#125;  {{ [[1d20cs0cf0 + @{PERCEPTION}  ]]Perception  = Survival[[1d20cs0cf0+@{Survival}]] &#125;&#125; {{ [[ (1d20cs0cf0+@{spellcraft}) * ceil(@{spellcraft-ranks}/100) ]]SpellCraft = 
| Skullduggery, @{selected|token_name} Skullduggery&#125;&#125; {{[[1d20cs0cf0 + @{Stealth} ]] Stealth= Disguise [[1d20cs0cf0 + @{Disguise} ]]&#125;&#125;  {{ [[1d20cs0cf0 + @{Escape-Artist}]] Escape = Disable [[(1d20cs0cf0 + @{disable-device}) * ceil(@{disable-device-ranks}/100)  ]]&#125;&#125; {{[[ (1d20cs0cf0 + @{sleight-of-hand}) * ceil(@{sleight-of-hand-ranks}/100) ]]Sleight=
| UMD, @{selected|token_name} UMD Check: [[ (1d20 + @{Use-Magic-Device}) * ceil(@{Use-Magic-Device-Ranks}/100)  ]] &#125;&#125; {{25 =Activate Blindly&#125;&#125;{{25 + Sp Lvl=Decipher Scroll&#125;&#125;{{20 + caster level=Use Scroll&#125;&#125;{{20=Use wand / Emulate class&#125;&#125;{{25=Emulate Race&#125;&#125;{{30=Emulate Align 
 } }}

Concentration Another drop-down beastie that will roll your Concentration Check(based on Spells tab of the Pathfinder Sheet) and prompt for which situation you're rolling against, level of the spell you're casting, and display the appropriate DC to beat

Copy/paste as-is

&{template:pf_generic} {{name=Concentration: [[1d20cs>1cf<20 + @{Concentration-0} ]] }} {{ ?{Concentration type?
|Casting Defensively, DC [[ 15 + (2 * ?&#123;Spell Level?&#125;)[SL] ]]=Casting Defensively
|Injured while casting, DC [[ 10 + ?&#123;Damage Taken?&#125;[DMG] + ?&#123;Spell Level?&#125;[SL] ]]=Injured while casting
|Continuous damage, DC [[ 10 + floor(0.5 * ?&#123;damage dealt?&#125;)[DMG] + ?&#123;Spell Level?&#125;[SL] ]]=Continuous damage
|Affected by a non-damaging spell, DC [[ ?&#123;DC of the affecting spell?&#125;[DC] + ?&#123;Spell Level?&#125;[SL] ]]=Affected by a non-damaging spell
|Grappled or pinned, DC [[ 10 + ?&#123;grappler's CMB?&#125;[CMB] + ?&#123;Spell Level?&#125;[SL] ]]=Grappled or pinned
|Entangled while casting, DC [[ 15 + ?&#123;Spell Level?&#125;[SL] ]]=Entangled while casting
|Vigorous motion, DC [[ 10 + ?&#123;Spell Level?&#125;[SL] ]]=Vigorous motion
|Violent motion, DC [[ 15 + ?&#123;Spell Level?&#125;[SL] ]]=Violent motion
|Extremely violent motion, DC [[ 20 + ?&#123;Spell Level?&#125;[SL] ]]=Extremely violent motion
|Wind with rain or sleet, DC [[ 5 + ?&#123;Spell Level?&#125;[SL] ]]=Wind with rain or sleet
|Wind with hail and debris, DC [[ 10 + ?&#123;Spell Level?&#125;[SL] ]]=Wind with hail and debris
|Weather caused by spell, (*see spell*)=Weather caused by spell} }}

SpellBook A Drop-Down query to select known Level 1 Spells. Includes all the relevant spellcaster fields from the Pathfinder Sheet, but manually lays out the format for a more condensed chat display (instead of the full text)

Copy/paste as-is

&{template:pf_spell} {{color=darkblue}} {{name=?{Level 1 Spells
| Identify, [Identify]( / [SpellCraft]( &#125;&#125; {{=[[1d20 + @{Spellcraft}+10 ]] ♦ [[1d20 + @{Spellcraft}+10 ]] ♦ [[1d20 + @{Spellcraft}+10 ]] ♦  [[1d20 + @{Spellcraft}+10 ]] ♦ [[1d20 + @{Spellcraft}+10 ]] ♦ [[1d20 + @{Spellcraft}+10 ]] 
| Grease, Grease &#125;&#125; {{name_link=;&#125; {{subtitle=*10' Square*&#125;&#125; {{close=range_pick&#125;&#125; {{range=[[@{spellclass-0-close}]]&#125;&#125;{{duration=*[[@{level}]] Minutes(D)* &#125;&#125; {{saving_throw=Reflex &#125;&#125; {{dc=*[[10[BASE] + 1[SL] + [[ @{INT-MOD} ]][INT] + 2[SF] +1[TRAIT] ]]* &#125;&#125;   {{Failed Save=``**Prone**``&#125;&#125; {{vs Item (*PerRound*)=``**Dropped**``&#125;&#125;    {{description=Acrobatics DC10 to Move 1/2 Speed. On Fail lose move and Save vs Prone    
| Liberating Command, Liberating Command &#125;&#125; {{name_link=;&#125; {{subtitle=*One Creature*&#125;&#125; {{close=range_pick&#125;&#125; {{range=[[@{spellclass-0-close}]]&#125;&#125; {{description=Target makes an Escape Artist Check + [[ [[ {(@{level}*2)&#44;20 &#125;kl1]] ]] 
| Magic Missile, Magic Missile &#125;&#125; {{name_link=;&#125; {{subtitle=*Up to 5 Targets • 15ft Apart*&#125;&#125; {{medium=range_pick&#125;&#125; {{range=[[@{spellclass-0-medium}]]&#125;&#125;{{sr=*[[1d20+@{spellclass-0-level-total}]]* &#125;&#125; {{MetaMagic=***Toppling***&#125;&#125; {{Bolts Cast=``[[ { 1 + floor(  (@{Level}-1) /2) &#44; 5 &#125;kl1 ]]``  &#125;&#125;   {{Bolt [[1]]=[[1d4+1]] Dmg + **CMB** [[1d20 + @{level} + @{Int-Mod} +2[Gloves]]] &#125;&#125;  {{Bolt [[2]]=[[1d4+1]] Dmg + **CMB** [[1d20 + @{level} + @{Int-Mod} +2[Gloves] ]] &#125;&#125; {{Bolt [[3]]=[[1d4+1]] Dmg + **CMB** [[1d20 + @{level} + @{Int-Mod} +2[Gloves]]] &#125;&#125; {{Bolt [[4]]=[[1d4+1]] Dmg + **CMB** [[1d20 + @{level} + @{Int-Mod} +2[Gloves]]] &#125;&#125; {{Bolt [[5]]=[[1d4+1]] Dmg + **CMB** [[1d20 + @{level} + @{Int-Mod} +2[Gloves] ]]
| Silent Image, Silent Image &#125;&#125; {{name_link=;&#125; {{subtitle=*[[ 4+ @{level} ]]x 10' Cubes*&#125;&#125; {{long=range_pick&#125;&#125; {{range=[[@{spellclass-0-long}]]&#125;&#125;{{duration=*Concentration* &#125;&#125; {{saving_throw=Will &#125;&#125; {{dc=*[[10[BASE] + 1[SL] + [[ @{INT-MOD}]][INT] + 0[SF] +0[TRAIT] ]]* &#125;&#125;  {{description=Visual illusion of an object creature or force. Can only move the image within its own effect.
| SnowBall, SnowBall&#125;&#125; {{name_link=;&#125; {{subtitle=*One ball of ice and snow*&#125;&#125; {{close=range_pick&#125;&#125; {{range=[[@{spellclass-0-close}]]&#125;&#125;{{saving_throw=Fort(*partial*) &#125;&#125; {{dc=*[[10[BASE] + 1[SL] + [[ @{INT-MOD}]][INT] + 2[SF] +0[TRAIT] ]]* &#125;&#125;  {{description=*Fort vs.* ***[Staggered](***
***R.Touch: [[1d20 + @{attk-ranged}  ]] for [[5d6]] dmg***
| Windy Escape , Windy Escape &#125;&#125; {{name_link=h;&#125; {{subtitle=*Immediate Action*&#125;&#125; {{description=Briefly gain DR 10/Magic and immunity to Poison • Sneak Attack • Critical Hits 
} }}

SpellBook Addendum You can create a link in your character journal's Bio tab to call the Level1, Level2, etc abilities once you have them configured. This lets you list your spells and "cast" them quickly from the BIO page of your character. Please note that this does not work with pop-out handouts.

On bio page, select some text and add a link.
Set the url to:   "~JournalName|AbilityName"
Example:  ~Gellius|Level3
If you ever edit the link later, it will try to put a / in front. Make sure you remove it.

All Cure Wands/Spells A drop-down query to use cure wands/potions, how many charges you're using, and displays it cleanly. Also includes drop-down options for the spell versions using the character's Caster Level from the Spells Tab of their Pathfinder Sheet.

Copy/Paste As-Is (assumes your casterlevel-0 reflects the class used to cast the cure spells)

&{template:pf_attack} {{color=darkblue}} {{Target=**@{target|Token_Name}** }}  ?{Cure Type
| Wand/Potion: CLW, {{name=Wand:Cure Light Wounds&#125;&#125; {{Charges:[[?{How many charges&#124;1&#125; ]]  =**Heal [[(?{How many charges&#124;1&#125;*1)d8 + (?{How many charges&#124;1&#125;*1) ]] HP** 
| Wand/Potion: CMW, {{name=Wand:Cure Moderate Wounds&#125;&#125; {{Charges:[[?{How many charges&#124;1&#125; ]] =**Heal [[(?{How many charges&#124;1&#125;*2)d8 + (?{How many charges&#124;1&#125;*3) ]] HP** 
| Wand/Potion: CSW, {{name=Wand:Cure Serious Wounds&#125;&#125; {{Charges:[[?{How many charges&#124;1&#125; ]] =**Heal [[(?{How many charges&#124;1&#125;*3)d8 + (?{How many charges&#124;1&#125;*5) ]] HP**
| Wand/Potion: CCW, {{name=Wand:Cure Critical Wounds&#125;&#125; {{Charges:[[?{How many charges&#124;1&#125; ]] =**Heal [[(?{How many charges&#124;1&#125;*4)d8 + (?{How many charges&#124;1&#125;*7) ]] HP** 
| -----------------------
| Lesser Restoration, {{name=Wand:Lesser Restoration&#125;&#125; {{Ability Damage =**Heal [[1d4]] Points** 
| -----------------------
| Spell: CLW, {{name=Spell:Cure Light Wounds&#125;&#125; {{Spell DC:[[@{spellclass-0-level-1-savedc}]]  =**Heal [[1d8+ {5&#44; @{spellclass-0-level} &#125;kl1 ]] HP** 
| Spell: CMW, {{name=Spell:Cure Moderate Wounds&#125;&#125; {{Spell DC:[[@{spellclass-0-level-2-savedc}]]  =**Heal [[2d8+ {10&#44; @{spellclass-0-level} &#125;kl1 ]] HP** 
| Spell: CSW, {{name=Spell:Cure Serious Wounds&#125;&#125; {{Spell DC:[[@{spellclass-0-level-3-savedc}]]  =**Heal [[3d8+ {15&#44; @{spellclass-0-level} &#125;kl1 ]] HP** 
| Spell: CCW, {{name=Spell:Cure Critical Wounds&#125;&#125; {{Spell DC:[[@{spellclass-0-level-4-savedc}]]  =**Heal [[4d8+ {20&#44; @{spellclass-0-level} &#125;kl1 ]] HP** } }}